Annotation of pgsql/configure.in, revision 1.207
1.1 petere 1: dnl Process this file with autoconf to produce a configure script.
1.207 ! momjian 2: dnl $Header: /cvsroot/pgsql-server/configure.in,v 1.206 2002/09/05 18:28:45 petere Exp $
1.185 petere 3: dnl
1.28 petere 4: dnl Developers, please strive to achieve this order:
5: dnl
6: dnl 0. Initialization and options processing
7: dnl 1. Programs
8: dnl 2. Libraries
9: dnl 3. Header files
10: dnl 4. Types
11: dnl 5. Structures
12: dnl 6. Compiler characteristics
13: dnl 7. Functions, global variables
14: dnl 8. System services
15: dnl
16: dnl Read the Autoconf manual for details.
1.185 petere 17: dnl
18: m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
19: dnl
1.32 petere 20: dnl The GNU folks apparently haven't heard that some people don't use
21: dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
1.171 petere 22: m4_define([info], [doc])
23: m4_define([infodir], [docdir])
1.204 momjian 24: AC_INIT([PostgreSQL], [7.3b1], [[email protected]])
1.171 petere 25: m4_undefine([infodir])
26: m4_undefine([info])
27: AC_SUBST(docdir)
28:
29: AC_PREREQ(2.53)
30: AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
31: AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
32: AC_CONFIG_AUX_DIR(config)
1.1 petere 33: AC_PREFIX_DEFAULT(/usr/local/pgsql)
1.171 petere 34: AC_SUBST(configure_args, [$ac_configure_args])
1.5 petere 35:
1.171 petere 36: AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
1.61 petere 37:
1.1 petere 38: AC_CANONICAL_HOST
39:
1.30 petere 40: template=
41: AC_MSG_CHECKING([which template to use])
42:
1.42 petere 43: PGAC_ARG_REQ(with, template, [],
44: [
45: case $withval in
1.30 petere 46: list) echo; ls "$srcdir/src/template"; exit;;
47: *) if test -f "$srcdir/src/template/$with_template" ; then
1.42 petere 48: template=$withval
1.30 petere 49: else
1.80 petere 50: AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
1.30 petere 51: fi;;
52: esac
1.42 petere 53: ],
54: [
55: # --with-template not given
1.30 petere 56:
57: case $host_os in
58: aix*) template=aix ;;
1.54 momjian 59: beos*) template=beos ;;
1.30 petere 60: bsdi*) template=bsdi ;;
61: cygwin*) template=win ;;
1.72 petere 62: darwin*) template=darwin ;;
1.30 petere 63: dgux*) template=dgux ;;
64: freebsd*) template=freebsd ;;
65: hpux*) template=hpux ;;
66: irix*) template=irix5 ;;
67: linux*) template=linux ;;
68: netbsd*) template=netbsd ;;
69: nextstep*) template=nextstep ;;
70: openbsd*) template=openbsd ;;
71: osf*) template=osf ;;
72: qnx*) template=qnx4 ;;
73: sco*) template=sco ;;
1.58 petere 74: solaris*) template=solaris ;;
1.30 petere 75: sunos*) template=sunos4 ;;
1.1 petere 76: sysv4.2*)
1.30 petere 77: case $host_vendor in
78: univel) template=univel ;;
79: esac ;;
80: sysv4*) template=svr4 ;;
1.133 petere 81: sysv5*) template=unixware ;;
1.30 petere 82: ultrix*) template=ultrix4 ;;
1.1 petere 83: esac
84:
1.30 petere 85: if test x"$template" = x"" ; then
1.80 petere 86: AC_MSG_ERROR([[
1.30 petere 87: *******************************************************************
88: PostgreSQL has apparently not been ported to your platform yet.
1.32 petere 89: To try a manual configuration, look into the src/template directory
1.80 petere 90: for a similar platform and use the '--with-template=' option.
1.30 petere 91:
92: Please also contact <[email protected]> to see about
1.80 petere 93: rectifying this. Include the above 'checking host system type...'
1.30 petere 94: line.
95: *******************************************************************
1.80 petere 96: ]])
1.30 petere 97: fi
98:
1.42 petere 99: ])
1.1 petere 100:
1.30 petere 101: AC_MSG_RESULT([$template])
1.1 petere 102:
1.30 petere 103: PORTNAME=$template
104: AC_SUBST(PORTNAME)
1.1 petere 105:
1.58 petere 106: # Pick right test-and-set (TAS) code. Most platforms have inline
107: # assembler code in src/include/storage/s_lock.h, so we just use
108: # a dummy file here.
109: case $host in
110: *-*-hpux*) need_tas=yes; tas_file=hpux.s ;;
111: sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
1.147 momjian 112: i?86-*-solaris*) need_tas=yes; tas_file=solaris_i386.s ;;
1.63 petere 113: *) need_tas=no; tas_file=dummy.s ;;
1.30 petere 114: esac
1.171 petere 115: AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
1.1 petere 116:
1.30 petere 117: if test "$need_tas" = yes ; then
118: TAS=tas.o
1.1 petere 119: fi
1.30 petere 120: AC_SUBST(TAS)
1.1 petere 121:
122:
123:
1.30 petere 124: ##
125: ## Command line options
126: ##
1.13 petere 127:
1.1 petere 128:
1.30 petere 129: #
130: # Add non-standard directories to the include path
131: #
1.42 petere 132: PGAC_ARG_REQ(with, includes, [ --with-includes=DIRS look for additional header files in DIRS])
1.1 petere 133:
134:
1.30 petere 135: #
136: # Add non-standard directories to the library search path
137: #
1.42 petere 138: PGAC_ARG_REQ(with, libraries, [ --with-libraries=DIRS look for additional libraries in DIRS],
139: [LIBRARY_DIRS=$withval])
1.1 petere 140:
1.42 petere 141: PGAC_ARG_REQ(with, libs, [ --with-libs=DIRS alternative spelling of --with-libraries],
142: [LIBRARY_DIRS=$withval])
1.2 petere 143:
1.1 petere 144:
1.29 petere 145: #
1.180 thomas 146: # 64-bit integer date/time storage (--enable-integer-datetimes)
147: #
148: AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
149: PGAC_ARG_BOOL(enable, integer-datetimes, no, [ --enable-integer-datetimes enable 64-bit integer date/time support],
150: [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
151: [Set to 1 if you want integer date/time support (--enable-integer-datetimes)])])
152: AC_MSG_RESULT([$enable_integer_datetimes])
153:
154:
1.42 petere 155: # Character set recode (--enable-recode)
1.29 petere 156: #
1.42 petere 157: AC_MSG_CHECKING([whether to build with recode support])
1.205 petere 158: PGAC_ARG_BOOL(enable, recode, no, [ --enable-recode enable single-byte recode support],
1.42 petere 159: [AC_DEFINE([CYR_RECODE], 1,
1.205 petere 160: [Set to 1 if you want single-byte recode support (--enable-recode)])])
1.29 petere 161: AC_MSG_RESULT([$enable_recode])
1.1 petere 162:
163:
1.70 ishii 164: #
1.128 petere 165: # NLS
166: #
167: AC_MSG_CHECKING([whether NLS is wanted])
168: PGAC_ARG_OPTARG(enable, nls,
1.171 petere 169: [[ --enable-nls[=LANGUAGES] enable Native Language Support]],
1.128 petere 170: [],
171: [WANTED_LANGUAGES=$enableval],
1.171 petere 172: [AC_DEFINE(ENABLE_NLS, 1,
173: [Define to 1 if you want National Language Support (--enable-nls)])])
1.128 petere 174: AC_MSG_RESULT([$enable_nls])
175: AC_SUBST(enable_nls)
176: AC_SUBST(WANTED_LANGUAGES)
177:
178: #
1.29 petere 179: # Default port number (--with-pgport), default 5432
180: #
181: AC_MSG_CHECKING([for default port number])
1.42 petere 182: PGAC_ARG_REQ(with, pgport, [ --with-pgport=PORTNUM change default port number [5432]],
183: [default_port=$withval],
184: [default_port=5432])
1.97 tgl 185: AC_MSG_RESULT([$default_port])
186: # Need both of these because some places want an integer and some a string
1.171 petere 187: AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
188: [The default TCP port number on which the server listens and to which
189: clients will try to connect to. This can be overridden at run-time,
190: but it's convenient if your clients have the right default compiled in.
191: (--with-pgport=PORTNUM)])
192: AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
193: [Default TCP port number as string constant])
1.97 tgl 194: AC_SUBST(default_port)
1.1 petere 195:
1.29 petere 196: #
197: # Maximum number of allowed connections (--with-maxbackends), default 32
198: #
199: AC_MSG_CHECKING([for default soft limit on number of connections])
1.42 petere 200: PGAC_ARG_REQ(with, maxbackends, [ --with-maxbackends=N set default maximum number of connections [32]],
201: [],
202: [with_maxbackends=32])
1.29 petere 203: AC_MSG_RESULT([$with_maxbackends])
1.42 petere 204: AC_DEFINE_UNQUOTED([DEF_MAXBACKENDS], [$with_maxbackends],
205: [The default soft limit on the number of concurrent connections, i.e., the default for the postmaster -N switch (--with-maxbackends)])
1.29 petere 206:
1.1 petere 207:
1.29 petere 208: #
1.65 petere 209: # Option to disable shared libraries
210: #
211: PGAC_ARG_BOOL(enable, shared, yes,
1.68 petere 212: [ --disable-shared do not build shared libraries])
1.65 petere 213: AC_SUBST(enable_shared)
214:
1.69 petere 215: #
216: # '-rpath'-like feature can be disabled
217: #
218: PGAC_ARG_BOOL(enable, rpath, yes,
219: [ --disable-rpath do not embed shared library search path in executables])
220: AC_SUBST(enable_rpath)
221:
1.65 petere 222:
223: #
1.74 petere 224: # --enable-debug adds -g to compiler flags
225: #
226: PGAC_ARG_BOOL(enable, debug, no,
227: [ --enable-debug build with debugging symbols (-g)])
1.168 momjian 228: AC_SUBST(enable_debug)
1.74 petere 229:
230: #
1.30 petere 231: # C compiler
232: #
233:
1.29 petere 234: # For historical reasons you can also use --with-CC to specify the C compiler
235: # to use, although the standard way to do this is to set the CC environment
236: # variable.
1.42 petere 237: PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
1.4 tgl 238:
1.171 petere 239: case $template in
240: aix) pgac_cc_list="gcc xlc";;
241: irix) pgac_cc_list="cc";; # no gcc
242: *) pgac_cc_list="gcc cc";;
243: esac
1.4 tgl 244:
1.171 petere 245: AC_PROG_CC([$pgac_cc_list])
1.30 petere 246: # Read the template
247: . "$srcdir/src/template/$template" || exit
1.74 petere 248:
1.171 petere 249: if test "$ac_env_CFLAGS_set" = set; then
250: CFLAGS=$ac_env_CFLAGS_value
1.74 petere 251: fi
252: if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
253: CFLAGS="$CFLAGS -g"
254: fi
1.171 petere 255: AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1.30 petere 256: # Check if the compiler still works with the template settings
1.171 petere 257: AC_MSG_CHECKING([whether the C compiler still works])
258: AC_TRY_LINK([], [return 0;],
259: [AC_MSG_RESULT(yes)],
260: [AC_MSG_RESULT(no)
261: AC_MSG_ERROR([cannot proceed])])
1.4 tgl 262: AC_PROG_CPP
1.6 petere 263: AC_SUBST(GCC)
1.4 tgl 264:
1.29 petere 265: # Create compiler version string
1.24 petere 266: if test x"$GCC" = x"yes" ; then
1.169 momjian 267: cc_string="GCC `${CC} --version | sed q`"
1.4 tgl 268: else
1.24 petere 269: cc_string=$CC
1.4 tgl 270: fi
1.174 tgl 271: AC_DEFINE_UNQUOTED(PG_VERSION_STR, ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"], [A canonical string containing the version number, platform, and C compiler])
1.24 petere 272:
1.4 tgl 273:
1.31 petere 274: #
275: # Automatic dependency tracking
276: #
1.42 petere 277: PGAC_ARG_BOOL(enable, depend, no, [ --enable-depend turn on automatic dependency tracking],
278: [autodepend=yes])
1.31 petere 279: AC_SUBST(autodepend)
280:
281:
1.42 petere 282: #
283: # Enable assert checks
284: #
285: PGAC_ARG_BOOL(enable, cassert, no, [ --enable-cassert enable assertion checks (for debugging)],
286: [AC_DEFINE([USE_ASSERT_CHECKING], 1,
287: [Define to 1 to build with assertion checks])])
1.30 petere 288:
289:
290: #
291: # Include directories
292: #
293: ac_save_IFS=$IFS
1.80 petere 294: IFS="${IFS}:"
1.30 petere 295: # SRCH_INC comes from the template file
296: for dir in $with_includes $SRCH_INC; do
297: if test -d "$dir"; then
298: INCLUDES="$INCLUDES -I$dir"
299: else
300: AC_MSG_WARN([*** Include directory $dir does not exist.])
301: fi
302: done
303: IFS=$ac_save_IFS
304: AC_SUBST(INCLUDES)
305:
306:
307: #
308: # Library directories
309: #
310: ac_save_IFS=$IFS
1.80 petere 311: IFS="${IFS}:"
1.30 petere 312: # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
313: for dir in $LIBRARY_DIRS $SRCH_LIB; do
314: if test -d "$dir"; then
1.68 petere 315: LIBDIRS="$LIBDIRS -L$dir"
1.30 petere 316: else
317: AC_MSG_WARN([*** Library directory $dir does not exist.])
318: fi
319: done
320: IFS=$ac_save_IFS
321:
322:
1.43 petere 323: #
324: # Tcl/Tk
325: #
326: AC_MSG_CHECKING([whether to build with Tcl])
327: PGAC_ARG_BOOL(with, tcl, no, [ --with-tcl build Tcl and Tk interfaces])
328: AC_MSG_RESULT([$with_tcl])
329: AC_SUBST([with_tcl])
330:
331: # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
332: AC_MSG_CHECKING([whether to build with Tk])
333: if test "$with_tcl" = yes; then
334: PGAC_ARG_BOOL(with, tk, yes, [ --without-tk do not build Tk interfaces if Tcl is enabled])
335: else
336: with_tk=no
337: fi
338: AC_MSG_RESULT([$with_tk])
339: AC_SUBST([with_tk])
1.1 petere 340:
341:
1.171 petere 342: # We see if the path to the Tcl/Tk configuration scripts is specified.
1.42 petere 343: # This will override the use of tclsh to find the paths to search.
344:
1.43 petere 345: PGAC_ARG_REQ(with, tclconfig, [ --with-tclconfig=DIR tclConfig.sh and tkConfig.sh are in DIR])
1.1 petere 346:
1.171 petere 347: # We see if the path to the Tk configuration scripts is specified.
1.42 petere 348: # This will override the use of tclsh to find the paths to search.
1.1 petere 349:
1.43 petere 350: PGAC_ARG_REQ(with, tkconfig, [ --with-tkconfig=DIR tkConfig.sh is in DIR])
1.125 petere 351:
1.42 petere 352: #
1.205 petere 353: # Optionally build Perl modules (PL/Perl)
1.199 momjian 354: #
355: AC_MSG_CHECKING([whether to build Perl modules])
1.205 petere 356: PGAC_ARG_BOOL(with, perl, no, [ --with-perl build Perl modules (PL/Perl)])
1.199 momjian 357: AC_MSG_RESULT([$with_perl])
358: AC_SUBST(with_perl)
359:
360: #
1.42 petere 361: # Optionally build Python interface module
362: #
363: AC_MSG_CHECKING([whether to build Python modules])
1.126 petere 364: PGAC_ARG_BOOL(with, python, no, [ --with-python build Python interface module])
365: AC_MSG_RESULT([$with_python])
1.5 petere 366: AC_SUBST(with_python)
1.1 petere 367:
1.105 peter 368: #
369: # Optionally build the Java/JDBC tools
370: #
371: AC_MSG_CHECKING([whether to build Java/JDBC tools])
1.108 petere 372: PGAC_ARG_BOOL(with, java, no, [ --with-java build JDBC interface and Java tools],
1.105 peter 373: [AC_MSG_RESULT(yes)
1.207 ! momjian 374: if test ! "$JAVA_HOME" -o ! -d "$JAVA_HOME" ; then
! 375: AC_MSG_ERROR([Set the JAVA_HOME environment variable to build Java components])
! 376: fi
1.108 petere 377: PGAC_PATH_ANT
378: if test -z "$ANT"; then
379: AC_MSG_ERROR([Ant is required to build Java components])
1.201 momjian 380: fi
381: if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
382: AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
1.108 petere 383: fi],
1.105 peter 384: [AC_MSG_RESULT(no)])
385: AC_SUBST(with_java)
1.13 petere 386:
1.28 petere 387: dnl A note on the Kerberos and OpenSSL options:
1.13 petere 388: dnl
1.28 petere 389: dnl The user can give an argument to the option in order the specify
390: dnl the base path of the respective installation (what he specified
391: dnl perhaps as --prefix). If no argument is given ($withval is "yes")
392: dnl then we take the path where the package installs by default. This
393: dnl way the user doesn't have to use redundant --with-includes and
394: dnl --with-libraries options, but he can still use them if the layout
395: dnl is non-standard.
396:
397: #
398: # Kerberos 4
399: #
1.171 petere 400: AC_MSG_CHECKING([whether to build with Kerberos 4 support])
401: PGAC_ARG_OPTARG(with, krb4, [[ --with-krb4[=DIR] build with Kerberos 4 support [/usr/athena]]],
1.42 petere 402: [krb4_prefix=/usr/athena],
403: [krb4_prefix=$withval],
404: [
1.171 petere 405: AC_MSG_RESULT(yes)
1.42 petere 406: AC_DEFINE(KRB4, 1, [Define if you are building with Kerberos 4 support.])
1.28 petere 407:
1.68 petere 408: if test -d "$krb4_prefix/include"; then
409: INCLUDES="$INCLUDES -I$krb4_prefix/include"
410: fi
411: if test -d "$krb4_prefix/lib"; then
412: LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
1.13 petere 413: fi
1.37 petere 414:
1.42 petere 415: krb_srvtab="/etc/srvtab"
1.171 petere 416: ],
417: [AC_MSG_RESULT(no)])
1.42 petere 418:
419: AC_SUBST(with_krb4)
1.13 petere 420:
421:
1.28 petere 422: #
423: # Kerberos 5
424: #
1.171 petere 425: AC_MSG_CHECKING([whether to build with Kerberos 5 support])
426: PGAC_ARG_OPTARG(with, krb5, [[ --with-krb5[=DIR] build with Kerberos 5 support [/usr/athena]]],
1.42 petere 427: [krb5_prefix=/usr/athena],
428: [krb5_prefix=$withval],
429: [
1.171 petere 430: AC_MSG_RESULT([yes])
1.42 petere 431: AC_DEFINE(KRB5, 1, [Define if you are building with Kerberos 5 support.])
1.28 petere 432:
1.68 petere 433: if test -d "$krb5_prefix/include"; then
434: INCLUDES="$INCLUDES -I$krb5_prefix/include"
435: fi
436: if test -d "$krb5_prefix/lib"; then
437: LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
1.13 petere 438: fi
1.28 petere 439:
1.42 petere 440: krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
1.171 petere 441: ],
442: [AC_MSG_RESULT(no)])
1.42 petere 443:
444: AC_SUBST(with_krb5)
1.28 petere 445:
446:
447: # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
448: if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
449: AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
450: fi
1.13 petere 451:
1.37 petere 452: AC_SUBST(krb_srvtab)
1.13 petere 453:
454:
1.28 petere 455: #
456: # Kerberos configuration parameters
457: #
1.42 petere 458: PGAC_ARG_REQ(with, krb-srvnam,
1.68 petere 459: [ --with-krb-srvnam=NAME name of the service principal in Kerberos [postgres]],
1.42 petere 460: [],
461: [with_krb_srvnam="postgres"])
462: AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
463: [The name of the PostgreSQL service principal in Kerberos])
1.13 petere 464:
1.28 petere 465:
1.136 momjian 466: #
467: # PAM
468: #
469: AC_MSG_CHECKING([whether to build with PAM support])
1.158 petere 470: PGAC_ARG_BOOL(with, pam, no,
471: [ --with-pam build with PAM support],
472: [AC_DEFINE([USE_PAM], 1, [Define to build with PAM support])])
473: AC_MSG_RESULT([$with_pam])
1.136 momjian 474: AC_SUBST(with_pam)
475:
1.28 petere 476:
477: #
478: # OpenSSL
479: #
1.42 petere 480: PGAC_ARG_OPTARG(with, openssl,
1.171 petere 481: [[ --with-openssl[=DIR] build with OpenSSL support [/usr/local/ssl]]],
1.42 petere 482: [openssl_prefix=/usr/local/ssl],
483: [openssl_prefix=$withval],
484: [
1.28 petere 485: AC_MSG_RESULT([building with OpenSSL support])
1.42 petere 486: AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support])
1.28 petere 487:
488: if test -d "${openssl_prefix}/include" ; then
489: INCLUDES="$INCLUDES -I${openssl_prefix}/include"
490: fi
491: if test -d "${openssl_prefix}/lib" ; then
1.68 petere 492: LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
1.28 petere 493: fi
1.42 petere 494: ])
495:
496: AC_SUBST(with_openssl)
1.28 petere 497:
1.13 petere 498:
1.177 petere 499: #
500: # Readline
501: #
502: PGAC_ARG_BOOL(with, readline, yes,
503: [ --without-readline do not use Readline])
504:
505: #
506: # Zlib
507: #
508: PGAC_ARG_BOOL(with, zlib, yes,
509: [ --without-zlib do not use Zlib])
1.3 momjian 510:
511:
512:
1.30 petere 513: # Assume system is ELF if it predefines __ELF__ as 1,
514: # otherwise believe host_os based default.
515: case $host_os in
1.127 momjian 516: freebsd1*|freebsd2*) elf=no;;
517: freebsd3*|freebsd4*) elf=yes;;
1.30 petere 518: esac
1.1 petere 519:
520: AC_EGREP_CPP(yes,
521: [#if __ELF__
522: yes
523: #endif
524: ],
1.30 petere 525: [ELF_SYS=true],
526: [if test "X$elf" = "Xyes" ; then
527: ELF_SYS=true
1.1 petere 528: else
1.30 petere 529: ELF_SYS=
530: fi])
531: AC_SUBST(ELF_SYS)
1.1 petere 532:
533:
534:
1.30 petere 535: CPPFLAGS="$CPPFLAGS $INCLUDES"
1.68 petere 536: LDFLAGS="$LDFLAGS $LIBDIRS"
1.30 petere 537:
1.171 petere 538: AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
539: AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1.30 petere 540:
541:
1.2 petere 542: AC_PROG_AWK
1.39 petere 543: PGAC_PATH_FLEX
1.1 petere 544: AC_PROG_LN_S
1.62 petere 545: AC_PROG_LD
1.67 petere 546: AC_SUBST(LD)
547: AC_SUBST(with_gnu_ld)
1.130 momjian 548: case $host_os in sysv5*)
1.77 petere 549: AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
550: [
551: pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
552: AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
553: LDFLAGS=$pgac_save_LDFLAGS
554: ])
555: ld_R_works=$pgac_cv_prog_ld_R
556: AC_SUBST(ld_R_works)
557: esac
1.1 petere 558: AC_PROG_RANLIB
1.58 petere 559: AC_CHECK_PROGS(LORDER, lorder)
1.56 petere 560: AC_PATH_PROG(TAR, tar)
1.176 petere 561: PGAC_CHECK_STRIP
1.98 petere 562:
563: AC_CHECK_PROGS(YACC, ['bison -y'])
564: if test -z "$YACC"; then
565: AC_MSG_WARN([
566: *** Without Bison you will not be able to build PostgreSQL from CVS or
567: *** change any of the parser definition files. You can obtain Bison from
568: *** a GNU mirror site. (If you are using the official distribution of
569: *** PostgreSQL then you do not need to worry about this because the Bison
570: *** output is pre-generated.) To use a different yacc program (possible,
571: *** but not recommended), set the environment variable YACC before running
572: *** 'configure'.])
573: fi
1.6 petere 574: AC_SUBST(YFLAGS)
1.98 petere 575:
1.199 momjian 576: PGAC_PATH_PERL
577: if test "$with_perl" = yes; then
1.205 petere 578: PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1.199 momjian 579: PGAC_CHECK_PERL_EMBED_LDFLAGS
1.126 petere 580: fi
581:
582: if test "$with_python" = yes; then
583: PGAC_PATH_PYTHON
584: PGAC_CHECK_PYTHON_MODULE_SETUP
585: PGAC_CHECK_PYTHON_EMBED_SETUP
1.43 petere 586: fi
1.1 petere 587:
588:
1.183 tgl 589: ##
1.29 petere 590: ## Libraries
591: ##
592:
1.1 petere 593: if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
594: then
595: AC_CHECK_LIB(bsd, main)
596: fi
1.21 petere 597: AC_CHECK_LIB(util, setproctitle)
1.1 petere 598: AC_CHECK_LIB(m, main)
599: AC_CHECK_LIB(dl, main)
1.181 momjian 600: AC_CHECK_LIB(nsl, main)
1.1 petere 601: AC_CHECK_LIB(socket, main)
602: AC_CHECK_LIB(ipc, main)
603: AC_CHECK_LIB(IPC, main)
604: AC_CHECK_LIB(lc, main)
605: AC_CHECK_LIB(dld, main)
606: AC_CHECK_LIB(ld, main)
607: AC_CHECK_LIB(compat, main)
608: AC_CHECK_LIB(BSD, main)
609: AC_CHECK_LIB(gen, main)
610: AC_CHECK_LIB(PW, main)
1.95 petere 611: AC_CHECK_LIB(resolv, main)
1.191 momjian 612: AC_SEARCH_LIBS(getopt_long, [getopt])
1.139 petere 613: # QNX:
1.104 petere 614: AC_CHECK_LIB([[unix]], main)
1.21 petere 615: AC_SEARCH_LIBS(crypt, crypt)
1.139 petere 616: # BeOS:
1.86 tgl 617: AC_CHECK_LIB(bind, __inet_ntoa)
1.139 petere 618: # Solaris:
1.140 petere 619: AC_SEARCH_LIBS(fdatasync, [rt posix4])
1.206 petere 620: # Cygwin:
621: AC_CHECK_LIB(cygipc, shmget)
1.28 petere 622:
1.177 petere 623: if test "$with_readline" = yes; then
624: PGAC_CHECK_READLINE
625: if test x"$pgac_cv_check_readline" = x"no"; then
626: AC_MSG_ERROR([readline library not found
627: Use --without-readline to disable readline support.])
628: fi
629: fi
630:
631: if test "$with_zlib" = yes; then
632: AC_CHECK_LIB(z, inflate, [],
633: [AC_MSG_ERROR([zlib library not found
634: Use --without-zlib to disable zlib support.])])
635: fi
636:
1.28 petere 637: if test "$with_krb4" = yes ; then
1.80 petere 638: AC_CHECK_LIB(des, [des_encrypt], [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
639: AC_CHECK_LIB(krb, [krb_sendauth], [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
1.28 petere 640: fi
641:
642: if test "$with_krb5" = yes ; then
1.166 petere 643: AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
644: [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
645: AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
646: [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
647: AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
648: [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
1.28 petere 649: fi
650:
651: if test "$with_openssl" = yes ; then
652: dnl Order matters!
1.80 petere 653: AC_CHECK_LIB(crypto, [CRYPTO_new_ex_data], [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
654: AC_CHECK_LIB(ssl, [SSL_library_init], [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1.128 petere 655: fi
656:
1.136 momjian 657: if test "$with_pam" = yes ; then
658: AC_CHECK_LIB(pam, [pam_start], [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
659: fi
660:
1.171 petere 661:
1.29 petere 662: ##
663: ## Header files
664: ##
1.194 petere 665:
1.171 petere 666: dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1.172 petere 667: AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h pwd.h sys/ipc.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h kernel/OS.h kernel/image.h SupportDefs.h])
1.66 tgl 668:
1.171 petere 669: # At least on IRIX, cpp test for netinet/tcp.h will fail unless
670: # netinet/in.h is included first.
1.66 tgl 671: AC_CHECK_HEADERS([netinet/in.h])
1.171 petere 672: AC_CHECK_HEADERS([netinet/tcp.h], [], [],
1.173 petere 673: [AC_INCLUDES_DEFAULT
674: #ifdef HAVE_NETINET_IN_H
1.66 tgl 675: #include <netinet/in.h>
676: #endif
1.171 petere 677: ])
1.73 petere 678:
1.177 petere 679: if test "$with_readline" = yes; then
680: AC_CHECK_HEADERS([readline/readline.h], [],
681: [AC_CHECK_HEADERS([readline.h], [],
682: [AC_MSG_ERROR([readline header not found
683: Use --without-readline to disable readline support.])])])
684: AC_CHECK_HEADERS([readline/history.h], [],
685: [AC_CHECK_HEADERS([history.h], [],
686: [AC_MSG_ERROR([history header not found
687: Use --without-readline to disable readline support.])])])
688: fi
689:
690: if test "$with_zlib" = yes; then
691: AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
692: Use --without-zlib to disable zlib support.])])
693: fi
1.15 petere 694:
1.28 petere 695: if test "$with_krb4" = yes ; then
696: AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
697: fi
698:
699: if test "$with_krb5" = yes ; then
700: AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
701: AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
702: fi
703:
704: if test "$with_openssl" = yes ; then
705: AC_CHECK_HEADER([openssl/ssl.h], [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
706: AC_CHECK_HEADER([openssl/err.h], [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1.136 momjian 707: fi
708:
709: if test "$with_pam" = yes ; then
710: AC_CHECK_HEADER([security/pam_appl.h], [], [AC_MSG_ERROR([header file <security/pam_appl.h> is required for PAM])])
1.28 petere 711: fi
712:
1.1 petere 713:
1.29 petere 714: ##
715: ## Types, structures, compiler characteristics
716: ##
1.194 petere 717:
1.171 petere 718: m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1.1 petere 719: AC_C_CONST
720: AC_C_INLINE
721: AC_C_STRINGIZE
1.40 petere 722: PGAC_C_SIGNED
1.171 petere 723: AC_C_VOLATILE
1.29 petere 724: AC_STRUCT_TIMEZONE
725: PGAC_UNION_SEMUN
1.44 petere 726: PGAC_STRUCT_SOCKADDR_UN
1.166 petere 727:
1.171 petere 728: AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
729: [#include <sys/param.h>
730: #include <sys/socket.h>
731: #include <sys/ucred.h>])
732:
1.177 petere 733: if test "$with_zlib" = yes; then
734: # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
735: # did not). While we could work around the lack of z_streamp, it
736: # seems unwise to encourage people to use such old zlib versions...
737: AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
738: Use --without-zlib to disable zlib support.])],
739: [#include <zlib.h>])
740: fi
741:
1.166 petere 742: if test "$with_krb5" = yes; then
743: # Check for differences between MIT and Heimdal (KTH) releases
1.171 petere 744: AC_CHECK_MEMBERS([krb5_ticket.enc_part2], [],
745: [AC_CHECK_MEMBERS([krb5_ticket.client], [],
746: [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
747: [#include <krb5.h>])],
748: [#include <krb5.h>])
749: AC_CHECK_MEMBERS([krb5_error.text.data], [],
1.205 petere 750: [AC_CHECK_MEMBERS([krb5_error.e_data], [],
751: [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
752: [#include <krb5.h>])],
1.171 petere 753: [#include <krb5.h>])
1.166 petere 754: fi
755:
1.1 petere 756:
1.29 petere 757: ##
758: ## Functions, global variables
759: ##
1.194 petere 760:
1.6 petere 761: PGAC_VAR_INT_TIMEZONE
1.29 petere 762: AC_FUNC_ACCEPT_ARGTYPES
1.6 petere 763: PGAC_FUNC_GETTIMEOFDAY_1ARG
1.1 petere 764:
1.159 momjian 765: # SunOS doesn't handle negative byte comparisons properly with +/- return
1.194 petere 766: AC_FUNC_MEMCMP
1.159 momjian 767:
1.171 petere 768: AC_CHECK_FUNCS([cbrt fcvt getopt_long memmove pstat setproctitle setsid sigprocmask sysconf waitpid dlopen fdatasync])
1.99 tgl 769:
1.171 petere 770: AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1.1 petere 771:
1.28 petere 772: AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
773: [AC_TRY_LINK(
774: [#include <machine/vmparam.h>
775: #include <sys/exec.h>
776: ],
1.1 petere 777: [PS_STRINGS->ps_nargvstr = 1;
778: PS_STRINGS->ps_argvstr = "foo";],
1.28 petere 779: [pgac_cv_var_PS_STRINGS=yes],
780: [pgac_cv_var_PS_STRINGS=no])])
781: if test "$pgac_cv_var_PS_STRINGS" = yes ; then
782: AC_DEFINE([HAVE_PS_STRINGS], [], [Define if the PS_STRINGS thing exists.])
783: fi
1.1 petere 784:
1.171 petere 785:
786: # We use our snprintf.c emulation if either snprintf() or vsnprintf()
787: # is missing. Yes, there are machines that have only one. We may
788: # also decide to use snprintf.c if snprintf() is present but does not
789: # have working "long long int" support -- see below.
790:
1.194 petere 791: pgac_need_repl_snprintf=no
792: AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
793: AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1.171 petere 794:
795:
796: # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
797: # include/c.h will provide declarations. Note this is a separate test
798: # from whether the functions exist in the C library --- there are
799: # systems that have the functions but don't bother to declare them :-(
800:
801: AC_CHECK_DECLS([snprintf, vsnprintf])
802:
1.29 petere 803:
804: # do this one the hard way in case isinf() is a macro
805: AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1.1 petere 806: [AC_TRY_LINK(
1.29 petere 807: [#include <math.h>
808: ],
1.1 petere 809: [double x = 0.0; int res = isinf(x);],
1.29 petere 810: [ac_cv_func_isinf=yes],
811: [ac_cv_func_isinf=no])])
812:
813: if test $ac_cv_func_isinf = yes ; then
1.171 petere 814: AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf()])
1.1 petere 815: else
1.194 petere 816: AC_LIBOBJ(isinf)
1.29 petere 817: # Look for a way to implement a substitute for isinf()
818: AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1.1 petere 819: fi
1.171 petere 820:
1.194 petere 821: AC_REPLACE_FUNCS([gethostname getrusage inet_aton random srandom strcasecmp strdup strerror strtol strtoul])
1.193 momjian 822:
1.194 petere 823: # Solaris has a very slow qsort in certain cases.
1.193 momjian 824: case $host_os in
1.194 petere 825: solaris*) AC_LIBOBJ(qsort) ;;
1.193 momjian 826: esac
1.1 petere 827:
828: # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
829: # this hackery with HPUXMATHLIB allows us to cope.
830: HPUXMATHLIB=""
1.30 petere 831: case $host_cpu in
1.1 petere 832: hppa1.1)
1.201 momjian 833: if test -r /lib/pa1.1/libm.a ; then
1.1 petere 834: HPUXMATHLIB="-L /lib/pa1.1 -lm"
835: fi ;;
836: esac
837: AC_SUBST(HPUXMATHLIB)
838:
1.171 petere 839: AC_CHECK_FUNCS(rint, [],
840: [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
1.1 petere 841:
1.52 petere 842:
1.177 petere 843: if test "$with_readline" = yes; then
844: PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
845: AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
846: fi
1.1 petere 847:
848:
849: dnl Cannot use AC_CHECK_FUNC because finite may be a macro
850: AC_MSG_CHECKING(for finite)
851: AC_TRY_LINK([#include <math.h>],
1.171 petere 852: [int dummy=finite(1.0);],
853: [AC_DEFINE(HAVE_FINITE, 1, [Set to 1 if you have finite()])
854: AC_MSG_RESULT(yes)],
855: [AC_MSG_RESULT(no)])
1.1 petere 856:
857: dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
858: dnl (especially on GNU libc)
1.133 petere 859: dnl See also comments in pg_config.h.
1.1 petere 860: AC_MSG_CHECKING(for sigsetjmp)
861: AC_TRY_LINK([#include <setjmp.h>],
1.171 petere 862: [sigjmp_buf x; sigsetjmp(x, 1);],
863: [AC_DEFINE(HAVE_SIGSETJMP, 1, [Set to 1 if you have sigsetjmp()])
864: AC_MSG_RESULT(yes)],
865: [AC_MSG_RESULT(no)])
1.1 petere 866:
1.182 ishii 867: AC_CHECK_FUNC(syslog,
868: [AC_CHECK_HEADER(syslog.h,
869: [AC_DEFINE(HAVE_SYSLOG, 1, [])],
870: [])])
1.1 petere 871:
1.76 petere 872: AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
873: [AC_TRY_LINK([#include <unistd.h>],
874: [extern int optreset; optreset = 1;],
875: [pgac_cv_var_int_optreset=yes],
876: [pgac_cv_var_int_optreset=no])])
877: if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1.171 petere 878: AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'])
1.76 petere 879: fi
880:
1.194 petere 881: AC_CHECK_FUNCS([strtoll strtoq], [break])
882: AC_CHECK_FUNCS([strtoull strtouq], [break])
883:
884: # Check for one of atexit() or on_exit()
885: AC_CHECK_FUNCS(atexit, [],
886: [AC_CHECK_FUNCS(on_exit, [],
887: [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
888:
1.195 petere 889: AC_FUNC_FSEEKO
890:
1.109 petere 891:
892: # This test makes sure that run tests work at all. Sometimes a shared
893: # library is found by the linker, but the runtime linker can't find it.
894: # This check should come after all modifications of compiler or linker
895: # variables, and before any other run tests.
896: AC_MSG_CHECKING([test program])
897: AC_TRY_RUN([int main() { return 0; }],
898: [AC_MSG_RESULT(ok)],
899: [AC_MSG_RESULT(failed)
900: AC_MSG_ERROR([[
901: *** Could not execute a simple test program. This may be a problem
902: *** related to locating shared libraries. Check the file 'config.log'
903: *** for the exact reason.]])],
904: [AC_MSG_RESULT([cross-compiling])])
905:
906:
1.1 petere 907: dnl Check to see if we have a working 64-bit integer type.
908: dnl This breaks down into two steps:
909: dnl (1) figure out if the compiler has a 64-bit int type with working
910: dnl arithmetic, and if so
911: dnl (2) see whether snprintf() can format the type correctly. (Currently,
912: dnl snprintf is the only library routine we really need for int8 support.)
913: dnl It's entirely possible to have a compiler that handles a 64-bit type
914: dnl when the C library doesn't; this is fairly likely when using gcc on
915: dnl an older platform, for example.
916: dnl If there is no native snprintf() or it does not handle the 64-bit type,
917: dnl we force our own version of snprintf() to be used instead.
918: dnl Note this test must be run after our initial check for snprintf/vsnprintf.
919:
1.6 petere 920: PGAC_TYPE_64BIT_INT([long int])
1.1 petere 921:
1.6 petere 922: if test x"$HAVE_LONG_INT_64" = x"no" ; then
923: PGAC_TYPE_64BIT_INT([long long int])
924: fi
1.1 petere 925:
926:
1.112 tgl 927: dnl If we need to use "long long int", figure out whether nnnLL notation works.
928:
1.201 momjian 929: if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1.112 tgl 930: AC_TRY_COMPILE([
931: #define INT64CONST(x) x##LL
932: long long int foo = INT64CONST(0x1234567890123456);
933: ],
934: [],
1.171 petere 935: [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define if you have LL constants])],
1.112 tgl 936: [])
937: fi
938:
939:
1.1 petere 940: dnl If we found "long int" is 64 bits, assume snprintf handles it.
941: dnl If we found we need to use "long long int", better check.
942: dnl We cope with snprintfs that use either %lld or %qd as the format.
943: dnl If neither works, fall back to our own snprintf emulation (which we
944: dnl know uses %lld).
945:
1.194 petere 946: if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
947: if test $pgac_need_repl_snprintf = no; then
1.1 petere 948: AC_MSG_CHECKING(whether snprintf handles 'long long int' as %lld)
949: AC_TRY_RUN([#include <stdio.h>
950: typedef long long int int64;
951: #define INT64_FORMAT "%lld"
952:
953: int64 a = 20000001;
954: int64 b = 40000005;
955:
956: int does_int64_snprintf_work()
957: {
958: int64 c;
959: char buf[100];
960:
961: if (sizeof(int64) != 8)
962: return 0; /* doesn't look like the right size */
963:
964: c = a * b;
965: snprintf(buf, 100, INT64_FORMAT, c);
966: if (strcmp(buf, "800000140000005") != 0)
967: return 0; /* either multiply or snprintf is busted */
968: return 1;
969: }
970: main() {
971: exit(! does_int64_snprintf_work());
972: }],
973: [ AC_MSG_RESULT(yes)
974: INT64_FORMAT='"%lld"'
975: ],
976: [ AC_MSG_RESULT(no)
977: AC_MSG_CHECKING(whether snprintf handles 'long long int' as %qd)
978: AC_TRY_RUN([#include <stdio.h>
979: typedef long long int int64;
980: #define INT64_FORMAT "%qd"
981:
982: int64 a = 20000001;
983: int64 b = 40000005;
984:
985: int does_int64_snprintf_work()
986: {
987: int64 c;
988: char buf[100];
989:
990: if (sizeof(int64) != 8)
991: return 0; /* doesn't look like the right size */
992:
993: c = a * b;
994: snprintf(buf, 100, INT64_FORMAT, c);
995: if (strcmp(buf, "800000140000005") != 0)
996: return 0; /* either multiply or snprintf is busted */
997: return 1;
998: }
999: main() {
1000: exit(! does_int64_snprintf_work());
1001: }],
1002: [ AC_MSG_RESULT(yes)
1003: INT64_FORMAT='"%qd"'
1004: ],
1005: [ AC_MSG_RESULT(no)
1006: # Force usage of our own snprintf, since system snprintf is broken
1.194 petere 1007: pgac_need_repl_snprintf=yes
1.1 petere 1008: INT64_FORMAT='"%lld"'
1009: ],
1.194 petere 1010: [ AC_MSG_RESULT([cannot test (not on host machine)])
1.1 petere 1011: # Force usage of our own snprintf, since we cannot test foreign snprintf
1.194 petere 1012: pgac_need_repl_snprintf=yes
1.1 petere 1013: INT64_FORMAT='"%lld"'
1014: ]) ],
1.194 petere 1015: [ AC_MSG_RESULT([cannot test (not on host machine)])
1.1 petere 1016: # Force usage of our own snprintf, since we cannot test foreign snprintf
1.194 petere 1017: pgac_need_repl_snprintf=yes
1.1 petere 1018: INT64_FORMAT='"%lld"'
1019: ])
1020: else
1021: # here if we previously decided we needed to use our own snprintf
1022: INT64_FORMAT='"%lld"'
1023: fi
1024: else
1025: # Here if we are not using 'long long int' at all
1026: INT64_FORMAT='"%ld"'
1027: fi
1028:
1.171 petere 1029: AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1030: [Define this as the appropriate snprintf format for 64-bit ints, if any])
1.1 petere 1031:
1.194 petere 1032: if test $pgac_need_repl_snprintf = yes; then
1033: AC_LIBOBJ(snprintf)
1034: fi
1.78 petere 1035:
1.84 tgl 1036: dnl Need a #define for the size of Datum (unsigned long)
1037:
1.171 petere 1038: AC_CHECK_SIZEOF([unsigned long])
1039: AC_DEFINE_UNQUOTED(SIZEOF_DATUM, $ac_cv_sizeof_unsigned_long, [sizeof(Datum) -- don't change])
1.84 tgl 1040:
1.171 petere 1041: # Determine memory alignment requirements for the basic C data types.
1.1 petere 1042:
1.6 petere 1043: PGAC_CHECK_ALIGNOF(short)
1044: PGAC_CHECK_ALIGNOF(int)
1045: PGAC_CHECK_ALIGNOF(long)
1.171 petere 1046: if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1.6 petere 1047: PGAC_CHECK_ALIGNOF(long long int)
1.1 petere 1048: fi
1.6 petere 1049: PGAC_CHECK_ALIGNOF(double)
1.1 petere 1050:
1.171 petere 1051: # Compute maximum alignment of any basic type.
1052: # We assume long's alignment is at least as strong as char, short, or int;
1053: # but we must check long long (if it exists) and double.
1054:
1055: MAX_ALIGNOF=$pgac_cv_alignof_long
1056: if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1057: MAX_ALIGNOF=$pgac_cv_alignof_double
1058: fi
1059: if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1060: MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1.1 petere 1061: fi
1.6 petere 1062: AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any type])
1.1 petere 1063:
1.155 petere 1064:
1.152 momjian 1065: # Some platforms predefine the types int8, int16, etc. Only check
1.171 petere 1066: # a (hopefully) representative subset.
1067: AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1068: [#include <stdio.h>
1.155 petere 1069: #ifdef HAVE_SUPPORTDEFS_H
1070: #include <SupportDefs.h>
1.171 petere 1071: #endif])
1.155 petere 1072:
1.171 petere 1073: # We also check for sig_atomic_t, which *should* be defined per ANSI
1074: # C, but is missing on some old platforms.
1075: AC_CHECK_TYPES([sig_atomic_t], [], [], [#include <signal.h>])
1.155 petere 1076:
1.152 momjian 1077:
1.6 petere 1078: PGAC_FUNC_POSIX_SIGNALS
1.195 petere 1079: if test $ac_cv_func_fseeko = yes; then
1080: AC_SYS_LARGEFILE
1081: fi
1.172 petere 1082:
1083:
1.184 tgl 1084: # Select semaphore implementation type.
1085: if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1086: AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores])
1087: SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1088: else
1089: if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1090: AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores])
1091: SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1092: else
1093: AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores])
1094: SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1095: fi
1096: fi
1097:
1098:
1099: # Select shared-memory implementation type.
1100: AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory])
1101: SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1102:
1103:
1.172 petere 1104: if test "$enable_nls" = yes ; then
1105: PGAC_CHECK_GETTEXT
1106: fi
1.1 petere 1107:
1.43 petere 1108: # Check for Tcl configuration script tclConfig.sh
1109: if test "$with_tcl" = yes; then
1110: PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1.185 petere 1111: PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1112: [TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1113: AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1.43 petere 1114: fi
1.1 petere 1115:
1.43 petere 1116: # Check for Tk configuration script tkConfig.sh
1117: if test "$with_tk" = yes; then
1118: PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1.185 petere 1119: PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1.1 petere 1120: fi
1121:
1122:
1.75 petere 1123: #
1124: # Check for DocBook and tools
1125: #
1126: PGAC_PROG_NSGMLS
1.178 petere 1127: PGAC_PROG_JADE
1128: PGAC_CHECK_DOCBOOK([3.1])
1129: PGAC_PATH_DOCBOOK_STYLESHEETS
1130: PGAC_PATH_COLLATEINDEX
1131: AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1.75 petere 1132:
1.61 petere 1133:
1.104 petere 1134: # prepare build tree if outside source tree
1.138 petere 1135: # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1136: # Note 2: /bin/pwd might be better than shell's built-in at getting
1137: # a symlink-free name.
1.171 petere 1138: if test "$no_create" != yes; then
1139: if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1.138 petere 1140: :
1.171 petere 1141: else
1142: AC_SUBST(vpath_build, yes)
1143: _AS_ECHO_N([preparing build tree... ])
1144: pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1145: $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1.104 petere 1146: || AC_MSG_ERROR(failed)
1147: AC_MSG_RESULT(done)
1.171 petere 1148: fi
1.61 petere 1149: fi
1.1 petere 1150:
1.171 petere 1151:
1152: AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1153:
1154: AC_CONFIG_LINKS([
1155: src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1.184 tgl 1156: src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1157: src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1.171 petere 1158: src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1159: src/include/pg_config_os.h:src/include/port/${template}.h
1160: src/Makefile.port:src/makefiles/Makefile.${template}
1161: ])
1162:
1163: AC_CONFIG_HEADERS([src/include/pg_config.h],
1.85 tgl 1164: [
1.133 petere 1165: # Update timestamp for pg_config.h (see Makefile.global)
1.171 petere 1166: echo >src/include/stamp-h
1.83 petere 1167: ])
1.171 petere 1168:
1169: AC_OUTPUT
PostgreSQL CVSweb <[email protected]>
![[BACK]](/https/anoncvs.postgresql.org/cvsweb/icons/back.gif){kind=icon}
Return to configure.in CVS log ![[TXT]](/https/anoncvs.postgresql.org/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/https/anoncvs.postgresql.org/cvsweb/icons/dir.gif){kind=icon}
Up to [PostgreSQL CVS Repository] / pgsql