Annotation of pgsql/configure.in, revision 1.209
1.1 petere 1: dnl Process this file with autoconf to produce a configure script.
1.209 ! momjian 2: dnl $Header: /cvsroot/pgsql-server/configure.in,v 1.208 2002/09/11 04:27:48 momjian Exp $
1.185 petere 3: dnl
1.28 petere 4: dnl Developers, please strive to achieve this order:
5: dnl
6: dnl 0. Initialization and options processing
7: dnl 1. Programs
8: dnl 2. Libraries
9: dnl 3. Header files
10: dnl 4. Types
11: dnl 5. Structures
12: dnl 6. Compiler characteristics
13: dnl 7. Functions, global variables
14: dnl 8. System services
15: dnl
16: dnl Read the Autoconf manual for details.
1.185 petere 17: dnl
18: m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
19: dnl
1.32 petere 20: dnl The GNU folks apparently haven't heard that some people don't use
21: dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
1.171 petere 22: m4_define([info], [doc])
23: m4_define([infodir], [docdir])
1.204 momjian 24: AC_INIT([PostgreSQL], [7.3b1], [[email protected]])
1.171 petere 25: m4_undefine([infodir])
26: m4_undefine([info])
27: AC_SUBST(docdir)
28:
29: AC_PREREQ(2.53)
30: AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
31: AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
32: AC_CONFIG_AUX_DIR(config)
1.1 petere 33: AC_PREFIX_DEFAULT(/usr/local/pgsql)
1.171 petere 34: AC_SUBST(configure_args, [$ac_configure_args])
1.5 petere 35:
1.171 petere 36: AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
1.61 petere 37:
1.1 petere 38: AC_CANONICAL_HOST
39:
1.30 petere 40: template=
41: AC_MSG_CHECKING([which template to use])
42:
1.42 petere 43: PGAC_ARG_REQ(with, template, [],
44: [
45: case $withval in
1.30 petere 46: list) echo; ls "$srcdir/src/template"; exit;;
47: *) if test -f "$srcdir/src/template/$with_template" ; then
1.42 petere 48: template=$withval
1.30 petere 49: else
1.80 petere 50: AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
1.30 petere 51: fi;;
52: esac
1.42 petere 53: ],
54: [
55: # --with-template not given
1.30 petere 56:
57: case $host_os in
58: aix*) template=aix ;;
1.54 momjian 59: beos*) template=beos ;;
1.30 petere 60: bsdi*) template=bsdi ;;
61: cygwin*) template=win ;;
1.72 petere 62: darwin*) template=darwin ;;
1.30 petere 63: dgux*) template=dgux ;;
64: freebsd*) template=freebsd ;;
65: hpux*) template=hpux ;;
66: irix*) template=irix5 ;;
67: linux*) template=linux ;;
68: netbsd*) template=netbsd ;;
69: nextstep*) template=nextstep ;;
70: openbsd*) template=openbsd ;;
71: osf*) template=osf ;;
72: qnx*) template=qnx4 ;;
73: sco*) template=sco ;;
1.58 petere 74: solaris*) template=solaris ;;
1.30 petere 75: sunos*) template=sunos4 ;;
1.1 petere 76: sysv4.2*)
1.30 petere 77: case $host_vendor in
78: univel) template=univel ;;
79: esac ;;
80: sysv4*) template=svr4 ;;
1.133 petere 81: sysv5*) template=unixware ;;
1.30 petere 82: ultrix*) template=ultrix4 ;;
1.1 petere 83: esac
84:
1.30 petere 85: if test x"$template" = x"" ; then
1.80 petere 86: AC_MSG_ERROR([[
1.30 petere 87: *******************************************************************
88: PostgreSQL has apparently not been ported to your platform yet.
1.32 petere 89: To try a manual configuration, look into the src/template directory
1.80 petere 90: for a similar platform and use the '--with-template=' option.
1.30 petere 91:
92: Please also contact <[email protected]> to see about
1.80 petere 93: rectifying this. Include the above 'checking host system type...'
1.30 petere 94: line.
95: *******************************************************************
1.80 petere 96: ]])
1.30 petere 97: fi
98:
1.42 petere 99: ])
1.1 petere 100:
1.30 petere 101: AC_MSG_RESULT([$template])
1.1 petere 102:
1.30 petere 103: PORTNAME=$template
104: AC_SUBST(PORTNAME)
1.1 petere 105:
1.58 petere 106: # Pick right test-and-set (TAS) code. Most platforms have inline
107: # assembler code in src/include/storage/s_lock.h, so we just use
108: # a dummy file here.
109: case $host in
110: *-*-hpux*) need_tas=yes; tas_file=hpux.s ;;
111: sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
1.147 momjian 112: i?86-*-solaris*) need_tas=yes; tas_file=solaris_i386.s ;;
1.63 petere 113: *) need_tas=no; tas_file=dummy.s ;;
1.30 petere 114: esac
1.171 petere 115: AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
1.1 petere 116:
1.30 petere 117: if test "$need_tas" = yes ; then
118: TAS=tas.o
1.1 petere 119: fi
1.30 petere 120: AC_SUBST(TAS)
1.1 petere 121:
122:
123:
1.30 petere 124: ##
125: ## Command line options
126: ##
1.13 petere 127:
1.1 petere 128:
1.30 petere 129: #
130: # Add non-standard directories to the include path
131: #
1.42 petere 132: PGAC_ARG_REQ(with, includes, [ --with-includes=DIRS look for additional header files in DIRS])
1.1 petere 133:
134:
1.30 petere 135: #
136: # Add non-standard directories to the library search path
137: #
1.42 petere 138: PGAC_ARG_REQ(with, libraries, [ --with-libraries=DIRS look for additional libraries in DIRS],
139: [LIBRARY_DIRS=$withval])
1.1 petere 140:
1.42 petere 141: PGAC_ARG_REQ(with, libs, [ --with-libs=DIRS alternative spelling of --with-libraries],
142: [LIBRARY_DIRS=$withval])
1.2 petere 143:
1.1 petere 144:
1.29 petere 145: #
1.180 thomas 146: # 64-bit integer date/time storage (--enable-integer-datetimes)
147: #
148: AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
149: PGAC_ARG_BOOL(enable, integer-datetimes, no, [ --enable-integer-datetimes enable 64-bit integer date/time support],
150: [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
151: [Set to 1 if you want integer date/time support (--enable-integer-datetimes)])])
152: AC_MSG_RESULT([$enable_integer_datetimes])
153:
154:
1.42 petere 155: # Character set recode (--enable-recode)
1.29 petere 156: #
1.42 petere 157: AC_MSG_CHECKING([whether to build with recode support])
1.205 petere 158: PGAC_ARG_BOOL(enable, recode, no, [ --enable-recode enable single-byte recode support],
1.42 petere 159: [AC_DEFINE([CYR_RECODE], 1,
1.205 petere 160: [Set to 1 if you want single-byte recode support (--enable-recode)])])
1.29 petere 161: AC_MSG_RESULT([$enable_recode])
1.1 petere 162:
163:
1.70 ishii 164: #
1.128 petere 165: # NLS
166: #
167: AC_MSG_CHECKING([whether NLS is wanted])
168: PGAC_ARG_OPTARG(enable, nls,
1.171 petere 169: [[ --enable-nls[=LANGUAGES] enable Native Language Support]],
1.128 petere 170: [],
171: [WANTED_LANGUAGES=$enableval],
1.171 petere 172: [AC_DEFINE(ENABLE_NLS, 1,
173: [Define to 1 if you want National Language Support (--enable-nls)])])
1.128 petere 174: AC_MSG_RESULT([$enable_nls])
175: AC_SUBST(enable_nls)
176: AC_SUBST(WANTED_LANGUAGES)
177:
178: #
1.29 petere 179: # Default port number (--with-pgport), default 5432
180: #
181: AC_MSG_CHECKING([for default port number])
1.42 petere 182: PGAC_ARG_REQ(with, pgport, [ --with-pgport=PORTNUM change default port number [5432]],
183: [default_port=$withval],
184: [default_port=5432])
1.97 tgl 185: AC_MSG_RESULT([$default_port])
186: # Need both of these because some places want an integer and some a string
1.171 petere 187: AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
188: [The default TCP port number on which the server listens and to which
189: clients will try to connect to. This can be overridden at run-time,
190: but it's convenient if your clients have the right default compiled in.
191: (--with-pgport=PORTNUM)])
192: AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
193: [Default TCP port number as string constant])
1.97 tgl 194: AC_SUBST(default_port)
1.1 petere 195:
1.29 petere 196: #
197: # Maximum number of allowed connections (--with-maxbackends), default 32
198: #
199: AC_MSG_CHECKING([for default soft limit on number of connections])
1.42 petere 200: PGAC_ARG_REQ(with, maxbackends, [ --with-maxbackends=N set default maximum number of connections [32]],
201: [],
202: [with_maxbackends=32])
1.29 petere 203: AC_MSG_RESULT([$with_maxbackends])
1.42 petere 204: AC_DEFINE_UNQUOTED([DEF_MAXBACKENDS], [$with_maxbackends],
205: [The default soft limit on the number of concurrent connections, i.e., the default for the postmaster -N switch (--with-maxbackends)])
1.29 petere 206:
1.1 petere 207:
1.29 petere 208: #
1.65 petere 209: # Option to disable shared libraries
210: #
211: PGAC_ARG_BOOL(enable, shared, yes,
1.68 petere 212: [ --disable-shared do not build shared libraries])
1.65 petere 213: AC_SUBST(enable_shared)
214:
1.69 petere 215: #
216: # '-rpath'-like feature can be disabled
217: #
218: PGAC_ARG_BOOL(enable, rpath, yes,
219: [ --disable-rpath do not embed shared library search path in executables])
220: AC_SUBST(enable_rpath)
221:
1.65 petere 222:
223: #
1.74 petere 224: # --enable-debug adds -g to compiler flags
225: #
226: PGAC_ARG_BOOL(enable, debug, no,
227: [ --enable-debug build with debugging symbols (-g)])
1.168 momjian 228: AC_SUBST(enable_debug)
1.74 petere 229:
230: #
1.30 petere 231: # C compiler
232: #
233:
1.29 petere 234: # For historical reasons you can also use --with-CC to specify the C compiler
235: # to use, although the standard way to do this is to set the CC environment
236: # variable.
1.42 petere 237: PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
1.4 tgl 238:
1.171 petere 239: case $template in
240: aix) pgac_cc_list="gcc xlc";;
241: irix) pgac_cc_list="cc";; # no gcc
242: *) pgac_cc_list="gcc cc";;
243: esac
1.4 tgl 244:
1.171 petere 245: AC_PROG_CC([$pgac_cc_list])
1.30 petere 246: # Read the template
247: . "$srcdir/src/template/$template" || exit
1.74 petere 248:
1.171 petere 249: if test "$ac_env_CFLAGS_set" = set; then
250: CFLAGS=$ac_env_CFLAGS_value
1.74 petere 251: fi
252: if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
253: CFLAGS="$CFLAGS -g"
254: fi
1.171 petere 255: AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1.30 petere 256: # Check if the compiler still works with the template settings
1.171 petere 257: AC_MSG_CHECKING([whether the C compiler still works])
258: AC_TRY_LINK([], [return 0;],
259: [AC_MSG_RESULT(yes)],
260: [AC_MSG_RESULT(no)
261: AC_MSG_ERROR([cannot proceed])])
1.4 tgl 262: AC_PROG_CPP
1.6 petere 263: AC_SUBST(GCC)
1.4 tgl 264:
1.29 petere 265: # Create compiler version string
1.24 petere 266: if test x"$GCC" = x"yes" ; then
1.169 momjian 267: cc_string="GCC `${CC} --version | sed q`"
1.4 tgl 268: else
1.24 petere 269: cc_string=$CC
1.4 tgl 270: fi
1.174 tgl 271: AC_DEFINE_UNQUOTED(PG_VERSION_STR, ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"], [A canonical string containing the version number, platform, and C compiler])
1.24 petere 272:
1.4 tgl 273:
1.31 petere 274: #
275: # Automatic dependency tracking
276: #
1.42 petere 277: PGAC_ARG_BOOL(enable, depend, no, [ --enable-depend turn on automatic dependency tracking],
278: [autodepend=yes])
1.31 petere 279: AC_SUBST(autodepend)
280:
281:
1.42 petere 282: #
283: # Enable assert checks
284: #
285: PGAC_ARG_BOOL(enable, cassert, no, [ --enable-cassert enable assertion checks (for debugging)],
286: [AC_DEFINE([USE_ASSERT_CHECKING], 1,
287: [Define to 1 to build with assertion checks])])
1.30 petere 288:
289:
290: #
291: # Include directories
292: #
293: ac_save_IFS=$IFS
1.80 petere 294: IFS="${IFS}:"
1.30 petere 295: # SRCH_INC comes from the template file
296: for dir in $with_includes $SRCH_INC; do
297: if test -d "$dir"; then
298: INCLUDES="$INCLUDES -I$dir"
299: else
300: AC_MSG_WARN([*** Include directory $dir does not exist.])
301: fi
302: done
303: IFS=$ac_save_IFS
304: AC_SUBST(INCLUDES)
305:
306:
307: #
308: # Library directories
309: #
310: ac_save_IFS=$IFS
1.80 petere 311: IFS="${IFS}:"
1.30 petere 312: # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
313: for dir in $LIBRARY_DIRS $SRCH_LIB; do
314: if test -d "$dir"; then
1.68 petere 315: LIBDIRS="$LIBDIRS -L$dir"
1.30 petere 316: else
317: AC_MSG_WARN([*** Library directory $dir does not exist.])
318: fi
319: done
320: IFS=$ac_save_IFS
321:
322:
1.43 petere 323: #
324: # Tcl/Tk
325: #
326: AC_MSG_CHECKING([whether to build with Tcl])
327: PGAC_ARG_BOOL(with, tcl, no, [ --with-tcl build Tcl and Tk interfaces])
328: AC_MSG_RESULT([$with_tcl])
329: AC_SUBST([with_tcl])
330:
331: # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
332: AC_MSG_CHECKING([whether to build with Tk])
333: if test "$with_tcl" = yes; then
334: PGAC_ARG_BOOL(with, tk, yes, [ --without-tk do not build Tk interfaces if Tcl is enabled])
335: else
336: with_tk=no
337: fi
338: AC_MSG_RESULT([$with_tk])
339: AC_SUBST([with_tk])
1.1 petere 340:
341:
1.171 petere 342: # We see if the path to the Tcl/Tk configuration scripts is specified.
1.42 petere 343: # This will override the use of tclsh to find the paths to search.
344:
1.43 petere 345: PGAC_ARG_REQ(with, tclconfig, [ --with-tclconfig=DIR tclConfig.sh and tkConfig.sh are in DIR])
1.1 petere 346:
1.171 petere 347: # We see if the path to the Tk configuration scripts is specified.
1.42 petere 348: # This will override the use of tclsh to find the paths to search.
1.1 petere 349:
1.43 petere 350: PGAC_ARG_REQ(with, tkconfig, [ --with-tkconfig=DIR tkConfig.sh is in DIR])
1.125 petere 351:
1.42 petere 352: #
1.205 petere 353: # Optionally build Perl modules (PL/Perl)
1.199 momjian 354: #
355: AC_MSG_CHECKING([whether to build Perl modules])
1.205 petere 356: PGAC_ARG_BOOL(with, perl, no, [ --with-perl build Perl modules (PL/Perl)])
1.199 momjian 357: AC_MSG_RESULT([$with_perl])
358: AC_SUBST(with_perl)
359:
360: #
1.42 petere 361: # Optionally build Python interface module
362: #
363: AC_MSG_CHECKING([whether to build Python modules])
1.126 petere 364: PGAC_ARG_BOOL(with, python, no, [ --with-python build Python interface module])
365: AC_MSG_RESULT([$with_python])
1.5 petere 366: AC_SUBST(with_python)
1.1 petere 367:
1.105 peter 368: #
369: # Optionally build the Java/JDBC tools
370: #
371: AC_MSG_CHECKING([whether to build Java/JDBC tools])
1.108 petere 372: PGAC_ARG_BOOL(with, java, no, [ --with-java build JDBC interface and Java tools],
1.105 peter 373: [AC_MSG_RESULT(yes)
1.108 petere 374: PGAC_PATH_ANT
375: if test -z "$ANT"; then
1.208 momjian 376: AC_MSG_ERROR([Ant is required to build Java components
377: If you have Ant already installed, see config.log for details on the failure.])
1.201 momjian 378: fi
379: if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
380: AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
1.108 petere 381: fi],
1.105 peter 382: [AC_MSG_RESULT(no)])
383: AC_SUBST(with_java)
1.13 petere 384:
1.28 petere 385: dnl A note on the Kerberos and OpenSSL options:
1.13 petere 386: dnl
1.28 petere 387: dnl The user can give an argument to the option in order the specify
388: dnl the base path of the respective installation (what he specified
389: dnl perhaps as --prefix). If no argument is given ($withval is "yes")
390: dnl then we take the path where the package installs by default. This
391: dnl way the user doesn't have to use redundant --with-includes and
392: dnl --with-libraries options, but he can still use them if the layout
393: dnl is non-standard.
394:
395: #
396: # Kerberos 4
397: #
1.171 petere 398: AC_MSG_CHECKING([whether to build with Kerberos 4 support])
399: PGAC_ARG_OPTARG(with, krb4, [[ --with-krb4[=DIR] build with Kerberos 4 support [/usr/athena]]],
1.42 petere 400: [krb4_prefix=/usr/athena],
401: [krb4_prefix=$withval],
402: [
1.171 petere 403: AC_MSG_RESULT(yes)
1.42 petere 404: AC_DEFINE(KRB4, 1, [Define if you are building with Kerberos 4 support.])
1.28 petere 405:
1.68 petere 406: if test -d "$krb4_prefix/include"; then
407: INCLUDES="$INCLUDES -I$krb4_prefix/include"
408: fi
409: if test -d "$krb4_prefix/lib"; then
410: LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
1.13 petere 411: fi
1.37 petere 412:
1.42 petere 413: krb_srvtab="/etc/srvtab"
1.171 petere 414: ],
415: [AC_MSG_RESULT(no)])
1.42 petere 416:
417: AC_SUBST(with_krb4)
1.13 petere 418:
419:
1.28 petere 420: #
421: # Kerberos 5
422: #
1.171 petere 423: AC_MSG_CHECKING([whether to build with Kerberos 5 support])
424: PGAC_ARG_OPTARG(with, krb5, [[ --with-krb5[=DIR] build with Kerberos 5 support [/usr/athena]]],
1.42 petere 425: [krb5_prefix=/usr/athena],
426: [krb5_prefix=$withval],
427: [
1.171 petere 428: AC_MSG_RESULT([yes])
1.42 petere 429: AC_DEFINE(KRB5, 1, [Define if you are building with Kerberos 5 support.])
1.28 petere 430:
1.68 petere 431: if test -d "$krb5_prefix/include"; then
432: INCLUDES="$INCLUDES -I$krb5_prefix/include"
433: fi
434: if test -d "$krb5_prefix/lib"; then
435: LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
1.13 petere 436: fi
1.28 petere 437:
1.42 petere 438: krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
1.171 petere 439: ],
440: [AC_MSG_RESULT(no)])
1.42 petere 441:
442: AC_SUBST(with_krb5)
1.28 petere 443:
444:
445: # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
446: if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
447: AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
448: fi
1.13 petere 449:
1.37 petere 450: AC_SUBST(krb_srvtab)
1.13 petere 451:
452:
1.28 petere 453: #
454: # Kerberos configuration parameters
455: #
1.42 petere 456: PGAC_ARG_REQ(with, krb-srvnam,
1.68 petere 457: [ --with-krb-srvnam=NAME name of the service principal in Kerberos [postgres]],
1.42 petere 458: [],
459: [with_krb_srvnam="postgres"])
460: AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
461: [The name of the PostgreSQL service principal in Kerberos])
1.13 petere 462:
1.28 petere 463:
1.136 momjian 464: #
465: # PAM
466: #
467: AC_MSG_CHECKING([whether to build with PAM support])
1.158 petere 468: PGAC_ARG_BOOL(with, pam, no,
469: [ --with-pam build with PAM support],
470: [AC_DEFINE([USE_PAM], 1, [Define to build with PAM support])])
471: AC_MSG_RESULT([$with_pam])
1.136 momjian 472: AC_SUBST(with_pam)
473:
1.28 petere 474:
475: #
476: # OpenSSL
477: #
1.42 petere 478: PGAC_ARG_OPTARG(with, openssl,
1.171 petere 479: [[ --with-openssl[=DIR] build with OpenSSL support [/usr/local/ssl]]],
1.42 petere 480: [openssl_prefix=/usr/local/ssl],
481: [openssl_prefix=$withval],
482: [
1.28 petere 483: AC_MSG_RESULT([building with OpenSSL support])
1.42 petere 484: AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support])
1.28 petere 485:
486: if test -d "${openssl_prefix}/include" ; then
487: INCLUDES="$INCLUDES -I${openssl_prefix}/include"
488: fi
489: if test -d "${openssl_prefix}/lib" ; then
1.68 petere 490: LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
1.28 petere 491: fi
1.42 petere 492: ])
493:
494: AC_SUBST(with_openssl)
1.28 petere 495:
1.13 petere 496:
1.177 petere 497: #
498: # Readline
499: #
500: PGAC_ARG_BOOL(with, readline, yes,
501: [ --without-readline do not use Readline])
502:
503: #
504: # Zlib
505: #
506: PGAC_ARG_BOOL(with, zlib, yes,
507: [ --without-zlib do not use Zlib])
1.3 momjian 508:
509:
510:
1.30 petere 511: # Assume system is ELF if it predefines __ELF__ as 1,
512: # otherwise believe host_os based default.
513: case $host_os in
1.127 momjian 514: freebsd1*|freebsd2*) elf=no;;
515: freebsd3*|freebsd4*) elf=yes;;
1.30 petere 516: esac
1.1 petere 517:
518: AC_EGREP_CPP(yes,
519: [#if __ELF__
520: yes
521: #endif
522: ],
1.30 petere 523: [ELF_SYS=true],
524: [if test "X$elf" = "Xyes" ; then
525: ELF_SYS=true
1.1 petere 526: else
1.30 petere 527: ELF_SYS=
528: fi])
529: AC_SUBST(ELF_SYS)
1.1 petere 530:
531:
532:
1.30 petere 533: CPPFLAGS="$CPPFLAGS $INCLUDES"
1.68 petere 534: LDFLAGS="$LDFLAGS $LIBDIRS"
1.30 petere 535:
1.171 petere 536: AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
537: AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1.30 petere 538:
539:
1.2 petere 540: AC_PROG_AWK
1.39 petere 541: PGAC_PATH_FLEX
1.1 petere 542: AC_PROG_LN_S
1.62 petere 543: AC_PROG_LD
1.67 petere 544: AC_SUBST(LD)
545: AC_SUBST(with_gnu_ld)
1.130 momjian 546: case $host_os in sysv5*)
1.77 petere 547: AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
548: [
549: pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
550: AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
551: LDFLAGS=$pgac_save_LDFLAGS
552: ])
553: ld_R_works=$pgac_cv_prog_ld_R
554: AC_SUBST(ld_R_works)
555: esac
1.1 petere 556: AC_PROG_RANLIB
1.58 petere 557: AC_CHECK_PROGS(LORDER, lorder)
1.56 petere 558: AC_PATH_PROG(TAR, tar)
1.176 petere 559: PGAC_CHECK_STRIP
1.98 petere 560:
561: AC_CHECK_PROGS(YACC, ['bison -y'])
562: if test -z "$YACC"; then
563: AC_MSG_WARN([
564: *** Without Bison you will not be able to build PostgreSQL from CVS or
565: *** change any of the parser definition files. You can obtain Bison from
566: *** a GNU mirror site. (If you are using the official distribution of
567: *** PostgreSQL then you do not need to worry about this because the Bison
568: *** output is pre-generated.) To use a different yacc program (possible,
569: *** but not recommended), set the environment variable YACC before running
570: *** 'configure'.])
571: fi
1.6 petere 572: AC_SUBST(YFLAGS)
1.98 petere 573:
1.199 momjian 574: PGAC_PATH_PERL
575: if test "$with_perl" = yes; then
1.205 petere 576: PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1.199 momjian 577: PGAC_CHECK_PERL_EMBED_LDFLAGS
1.126 petere 578: fi
579:
580: if test "$with_python" = yes; then
581: PGAC_PATH_PYTHON
582: PGAC_CHECK_PYTHON_MODULE_SETUP
583: PGAC_CHECK_PYTHON_EMBED_SETUP
1.43 petere 584: fi
1.1 petere 585:
586:
1.183 tgl 587: ##
1.29 petere 588: ## Libraries
589: ##
590:
1.1 petere 591: if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
592: then
593: AC_CHECK_LIB(bsd, main)
594: fi
1.21 petere 595: AC_CHECK_LIB(util, setproctitle)
1.1 petere 596: AC_CHECK_LIB(m, main)
597: AC_CHECK_LIB(dl, main)
1.181 momjian 598: AC_CHECK_LIB(nsl, main)
1.1 petere 599: AC_CHECK_LIB(socket, main)
600: AC_CHECK_LIB(ipc, main)
601: AC_CHECK_LIB(IPC, main)
602: AC_CHECK_LIB(lc, main)
603: AC_CHECK_LIB(dld, main)
604: AC_CHECK_LIB(ld, main)
605: AC_CHECK_LIB(compat, main)
606: AC_CHECK_LIB(BSD, main)
607: AC_CHECK_LIB(gen, main)
608: AC_CHECK_LIB(PW, main)
1.95 petere 609: AC_CHECK_LIB(resolv, main)
1.209 ! momjian 610: AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1.139 petere 611: # QNX:
1.104 petere 612: AC_CHECK_LIB([[unix]], main)
1.21 petere 613: AC_SEARCH_LIBS(crypt, crypt)
1.139 petere 614: # BeOS:
1.86 tgl 615: AC_CHECK_LIB(bind, __inet_ntoa)
1.139 petere 616: # Solaris:
1.140 petere 617: AC_SEARCH_LIBS(fdatasync, [rt posix4])
1.206 petere 618: # Cygwin:
619: AC_CHECK_LIB(cygipc, shmget)
1.28 petere 620:
1.177 petere 621: if test "$with_readline" = yes; then
622: PGAC_CHECK_READLINE
623: if test x"$pgac_cv_check_readline" = x"no"; then
624: AC_MSG_ERROR([readline library not found
1.208 momjian 625: If you have readline already installed, see config.log for details on the
626: failure. It is possible the compiler isn't looking in the proper directory.
1.177 petere 627: Use --without-readline to disable readline support.])
628: fi
629: fi
630:
631: if test "$with_zlib" = yes; then
632: AC_CHECK_LIB(z, inflate, [],
633: [AC_MSG_ERROR([zlib library not found
1.208 momjian 634: If you have zlib already installed, see config.log for details on the
635: failure. It is possible the compiler isn't looking in the proper directory.
1.177 petere 636: Use --without-zlib to disable zlib support.])])
637: fi
638:
1.28 petere 639: if test "$with_krb4" = yes ; then
1.80 petere 640: AC_CHECK_LIB(des, [des_encrypt], [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
641: AC_CHECK_LIB(krb, [krb_sendauth], [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
1.28 petere 642: fi
643:
644: if test "$with_krb5" = yes ; then
1.166 petere 645: AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
646: [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
647: AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
648: [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
649: AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
650: [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
1.28 petere 651: fi
652:
653: if test "$with_openssl" = yes ; then
654: dnl Order matters!
1.80 petere 655: AC_CHECK_LIB(crypto, [CRYPTO_new_ex_data], [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
656: AC_CHECK_LIB(ssl, [SSL_library_init], [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1.128 petere 657: fi
658:
1.136 momjian 659: if test "$with_pam" = yes ; then
660: AC_CHECK_LIB(pam, [pam_start], [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
661: fi
662:
1.171 petere 663:
1.29 petere 664: ##
665: ## Header files
666: ##
1.194 petere 667:
1.171 petere 668: dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1.172 petere 669: AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h pwd.h sys/ipc.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h kernel/OS.h kernel/image.h SupportDefs.h])
1.66 tgl 670:
1.171 petere 671: # At least on IRIX, cpp test for netinet/tcp.h will fail unless
672: # netinet/in.h is included first.
1.66 tgl 673: AC_CHECK_HEADERS([netinet/in.h])
1.171 petere 674: AC_CHECK_HEADERS([netinet/tcp.h], [], [],
1.173 petere 675: [AC_INCLUDES_DEFAULT
676: #ifdef HAVE_NETINET_IN_H
1.66 tgl 677: #include <netinet/in.h>
678: #endif
1.171 petere 679: ])
1.73 petere 680:
1.177 petere 681: if test "$with_readline" = yes; then
682: AC_CHECK_HEADERS([readline/readline.h], [],
683: [AC_CHECK_HEADERS([readline.h], [],
684: [AC_MSG_ERROR([readline header not found
1.208 momjian 685: If you have readline already installed, see config.log for details on the
686: failure. It is possible the compiler isn't looking in the proper directory.
1.177 petere 687: Use --without-readline to disable readline support.])])])
688: AC_CHECK_HEADERS([readline/history.h], [],
689: [AC_CHECK_HEADERS([history.h], [],
690: [AC_MSG_ERROR([history header not found
1.208 momjian 691: If you have readline already installed, see config.log for details on the
692: failure. It is possible the compiler isn't looking in the proper directory.
1.177 petere 693: Use --without-readline to disable readline support.])])])
694: fi
695:
696: if test "$with_zlib" = yes; then
697: AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1.208 momjian 698: If you have readline already installed, see config.log for details on the
699: failure. It is possible the compiler isn't looking in the proper directory.
1.177 petere 700: Use --without-zlib to disable zlib support.])])
701: fi
1.15 petere 702:
1.28 petere 703: if test "$with_krb4" = yes ; then
704: AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
705: fi
706:
707: if test "$with_krb5" = yes ; then
708: AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
709: AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
710: fi
711:
712: if test "$with_openssl" = yes ; then
713: AC_CHECK_HEADER([openssl/ssl.h], [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
714: AC_CHECK_HEADER([openssl/err.h], [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1.136 momjian 715: fi
716:
717: if test "$with_pam" = yes ; then
718: AC_CHECK_HEADER([security/pam_appl.h], [], [AC_MSG_ERROR([header file <security/pam_appl.h> is required for PAM])])
1.28 petere 719: fi
720:
1.1 petere 721:
1.29 petere 722: ##
723: ## Types, structures, compiler characteristics
724: ##
1.194 petere 725:
1.171 petere 726: m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1.1 petere 727: AC_C_CONST
728: AC_C_INLINE
729: AC_C_STRINGIZE
1.40 petere 730: PGAC_C_SIGNED
1.171 petere 731: AC_C_VOLATILE
1.29 petere 732: AC_STRUCT_TIMEZONE
733: PGAC_UNION_SEMUN
1.44 petere 734: PGAC_STRUCT_SOCKADDR_UN
1.166 petere 735:
1.171 petere 736: AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
737: [#include <sys/param.h>
738: #include <sys/socket.h>
739: #include <sys/ucred.h>])
740:
1.177 petere 741: if test "$with_zlib" = yes; then
742: # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
743: # did not). While we could work around the lack of z_streamp, it
744: # seems unwise to encourage people to use such old zlib versions...
745: AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
746: Use --without-zlib to disable zlib support.])],
747: [#include <zlib.h>])
748: fi
749:
1.166 petere 750: if test "$with_krb5" = yes; then
751: # Check for differences between MIT and Heimdal (KTH) releases
1.171 petere 752: AC_CHECK_MEMBERS([krb5_ticket.enc_part2], [],
753: [AC_CHECK_MEMBERS([krb5_ticket.client], [],
754: [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
755: [#include <krb5.h>])],
756: [#include <krb5.h>])
757: AC_CHECK_MEMBERS([krb5_error.text.data], [],
1.205 petere 758: [AC_CHECK_MEMBERS([krb5_error.e_data], [],
759: [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
760: [#include <krb5.h>])],
1.171 petere 761: [#include <krb5.h>])
1.166 petere 762: fi
763:
1.1 petere 764:
1.29 petere 765: ##
766: ## Functions, global variables
767: ##
1.194 petere 768:
1.6 petere 769: PGAC_VAR_INT_TIMEZONE
1.29 petere 770: AC_FUNC_ACCEPT_ARGTYPES
1.6 petere 771: PGAC_FUNC_GETTIMEOFDAY_1ARG
1.1 petere 772:
1.159 momjian 773: # SunOS doesn't handle negative byte comparisons properly with +/- return
1.194 petere 774: AC_FUNC_MEMCMP
1.159 momjian 775:
1.171 petere 776: AC_CHECK_FUNCS([cbrt fcvt getopt_long memmove pstat setproctitle setsid sigprocmask sysconf waitpid dlopen fdatasync])
1.99 tgl 777:
1.171 petere 778: AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1.1 petere 779:
1.28 petere 780: AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
781: [AC_TRY_LINK(
782: [#include <machine/vmparam.h>
783: #include <sys/exec.h>
784: ],
1.1 petere 785: [PS_STRINGS->ps_nargvstr = 1;
786: PS_STRINGS->ps_argvstr = "foo";],
1.28 petere 787: [pgac_cv_var_PS_STRINGS=yes],
788: [pgac_cv_var_PS_STRINGS=no])])
789: if test "$pgac_cv_var_PS_STRINGS" = yes ; then
790: AC_DEFINE([HAVE_PS_STRINGS], [], [Define if the PS_STRINGS thing exists.])
791: fi
1.1 petere 792:
1.171 petere 793:
794: # We use our snprintf.c emulation if either snprintf() or vsnprintf()
795: # is missing. Yes, there are machines that have only one. We may
796: # also decide to use snprintf.c if snprintf() is present but does not
797: # have working "long long int" support -- see below.
798:
1.194 petere 799: pgac_need_repl_snprintf=no
800: AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
801: AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1.171 petere 802:
803:
804: # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
805: # include/c.h will provide declarations. Note this is a separate test
806: # from whether the functions exist in the C library --- there are
807: # systems that have the functions but don't bother to declare them :-(
808:
809: AC_CHECK_DECLS([snprintf, vsnprintf])
810:
1.29 petere 811:
812: # do this one the hard way in case isinf() is a macro
813: AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1.1 petere 814: [AC_TRY_LINK(
1.29 petere 815: [#include <math.h>
816: ],
1.1 petere 817: [double x = 0.0; int res = isinf(x);],
1.29 petere 818: [ac_cv_func_isinf=yes],
819: [ac_cv_func_isinf=no])])
820:
821: if test $ac_cv_func_isinf = yes ; then
1.171 petere 822: AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf()])
1.1 petere 823: else
1.194 petere 824: AC_LIBOBJ(isinf)
1.29 petere 825: # Look for a way to implement a substitute for isinf()
826: AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1.1 petere 827: fi
1.171 petere 828:
1.194 petere 829: AC_REPLACE_FUNCS([gethostname getrusage inet_aton random srandom strcasecmp strdup strerror strtol strtoul])
1.193 momjian 830:
1.194 petere 831: # Solaris has a very slow qsort in certain cases.
1.193 momjian 832: case $host_os in
1.194 petere 833: solaris*) AC_LIBOBJ(qsort) ;;
1.193 momjian 834: esac
1.1 petere 835:
836: # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
837: # this hackery with HPUXMATHLIB allows us to cope.
838: HPUXMATHLIB=""
1.30 petere 839: case $host_cpu in
1.1 petere 840: hppa1.1)
1.201 momjian 841: if test -r /lib/pa1.1/libm.a ; then
1.1 petere 842: HPUXMATHLIB="-L /lib/pa1.1 -lm"
843: fi ;;
844: esac
845: AC_SUBST(HPUXMATHLIB)
846:
1.171 petere 847: AC_CHECK_FUNCS(rint, [],
848: [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
1.1 petere 849:
1.52 petere 850:
1.177 petere 851: if test "$with_readline" = yes; then
852: PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
853: AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
854: fi
1.1 petere 855:
856:
857: dnl Cannot use AC_CHECK_FUNC because finite may be a macro
858: AC_MSG_CHECKING(for finite)
859: AC_TRY_LINK([#include <math.h>],
1.171 petere 860: [int dummy=finite(1.0);],
861: [AC_DEFINE(HAVE_FINITE, 1, [Set to 1 if you have finite()])
862: AC_MSG_RESULT(yes)],
863: [AC_MSG_RESULT(no)])
1.1 petere 864:
865: dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
866: dnl (especially on GNU libc)
1.133 petere 867: dnl See also comments in pg_config.h.
1.1 petere 868: AC_MSG_CHECKING(for sigsetjmp)
869: AC_TRY_LINK([#include <setjmp.h>],
1.171 petere 870: [sigjmp_buf x; sigsetjmp(x, 1);],
871: [AC_DEFINE(HAVE_SIGSETJMP, 1, [Set to 1 if you have sigsetjmp()])
872: AC_MSG_RESULT(yes)],
873: [AC_MSG_RESULT(no)])
1.1 petere 874:
1.182 ishii 875: AC_CHECK_FUNC(syslog,
876: [AC_CHECK_HEADER(syslog.h,
877: [AC_DEFINE(HAVE_SYSLOG, 1, [])],
878: [])])
1.1 petere 879:
1.76 petere 880: AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
881: [AC_TRY_LINK([#include <unistd.h>],
882: [extern int optreset; optreset = 1;],
883: [pgac_cv_var_int_optreset=yes],
884: [pgac_cv_var_int_optreset=no])])
885: if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1.171 petere 886: AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'])
1.76 petere 887: fi
888:
1.194 petere 889: AC_CHECK_FUNCS([strtoll strtoq], [break])
890: AC_CHECK_FUNCS([strtoull strtouq], [break])
891:
892: # Check for one of atexit() or on_exit()
893: AC_CHECK_FUNCS(atexit, [],
894: [AC_CHECK_FUNCS(on_exit, [],
895: [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
896:
1.195 petere 897: AC_FUNC_FSEEKO
898:
1.109 petere 899:
900: # This test makes sure that run tests work at all. Sometimes a shared
901: # library is found by the linker, but the runtime linker can't find it.
902: # This check should come after all modifications of compiler or linker
903: # variables, and before any other run tests.
904: AC_MSG_CHECKING([test program])
905: AC_TRY_RUN([int main() { return 0; }],
906: [AC_MSG_RESULT(ok)],
907: [AC_MSG_RESULT(failed)
908: AC_MSG_ERROR([[
909: *** Could not execute a simple test program. This may be a problem
910: *** related to locating shared libraries. Check the file 'config.log'
911: *** for the exact reason.]])],
912: [AC_MSG_RESULT([cross-compiling])])
913:
914:
1.1 petere 915: dnl Check to see if we have a working 64-bit integer type.
916: dnl This breaks down into two steps:
917: dnl (1) figure out if the compiler has a 64-bit int type with working
918: dnl arithmetic, and if so
919: dnl (2) see whether snprintf() can format the type correctly. (Currently,
920: dnl snprintf is the only library routine we really need for int8 support.)
921: dnl It's entirely possible to have a compiler that handles a 64-bit type
922: dnl when the C library doesn't; this is fairly likely when using gcc on
923: dnl an older platform, for example.
924: dnl If there is no native snprintf() or it does not handle the 64-bit type,
925: dnl we force our own version of snprintf() to be used instead.
926: dnl Note this test must be run after our initial check for snprintf/vsnprintf.
927:
1.6 petere 928: PGAC_TYPE_64BIT_INT([long int])
1.1 petere 929:
1.6 petere 930: if test x"$HAVE_LONG_INT_64" = x"no" ; then
931: PGAC_TYPE_64BIT_INT([long long int])
932: fi
1.1 petere 933:
934:
1.112 tgl 935: dnl If we need to use "long long int", figure out whether nnnLL notation works.
936:
1.201 momjian 937: if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1.112 tgl 938: AC_TRY_COMPILE([
939: #define INT64CONST(x) x##LL
940: long long int foo = INT64CONST(0x1234567890123456);
941: ],
942: [],
1.171 petere 943: [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define if you have LL constants])],
1.112 tgl 944: [])
945: fi
946:
947:
1.1 petere 948: dnl If we found "long int" is 64 bits, assume snprintf handles it.
949: dnl If we found we need to use "long long int", better check.
950: dnl We cope with snprintfs that use either %lld or %qd as the format.
951: dnl If neither works, fall back to our own snprintf emulation (which we
952: dnl know uses %lld).
953:
1.194 petere 954: if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
955: if test $pgac_need_repl_snprintf = no; then
1.1 petere 956: AC_MSG_CHECKING(whether snprintf handles 'long long int' as %lld)
957: AC_TRY_RUN([#include <stdio.h>
958: typedef long long int int64;
959: #define INT64_FORMAT "%lld"
960:
961: int64 a = 20000001;
962: int64 b = 40000005;
963:
964: int does_int64_snprintf_work()
965: {
966: int64 c;
967: char buf[100];
968:
969: if (sizeof(int64) != 8)
970: return 0; /* doesn't look like the right size */
971:
972: c = a * b;
973: snprintf(buf, 100, INT64_FORMAT, c);
974: if (strcmp(buf, "800000140000005") != 0)
975: return 0; /* either multiply or snprintf is busted */
976: return 1;
977: }
978: main() {
979: exit(! does_int64_snprintf_work());
980: }],
981: [ AC_MSG_RESULT(yes)
982: INT64_FORMAT='"%lld"'
983: ],
984: [ AC_MSG_RESULT(no)
985: AC_MSG_CHECKING(whether snprintf handles 'long long int' as %qd)
986: AC_TRY_RUN([#include <stdio.h>
987: typedef long long int int64;
988: #define INT64_FORMAT "%qd"
989:
990: int64 a = 20000001;
991: int64 b = 40000005;
992:
993: int does_int64_snprintf_work()
994: {
995: int64 c;
996: char buf[100];
997:
998: if (sizeof(int64) != 8)
999: return 0; /* doesn't look like the right size */
1000:
1001: c = a * b;
1002: snprintf(buf, 100, INT64_FORMAT, c);
1003: if (strcmp(buf, "800000140000005") != 0)
1004: return 0; /* either multiply or snprintf is busted */
1005: return 1;
1006: }
1007: main() {
1008: exit(! does_int64_snprintf_work());
1009: }],
1010: [ AC_MSG_RESULT(yes)
1011: INT64_FORMAT='"%qd"'
1012: ],
1013: [ AC_MSG_RESULT(no)
1014: # Force usage of our own snprintf, since system snprintf is broken
1.194 petere 1015: pgac_need_repl_snprintf=yes
1.1 petere 1016: INT64_FORMAT='"%lld"'
1017: ],
1.194 petere 1018: [ AC_MSG_RESULT([cannot test (not on host machine)])
1.1 petere 1019: # Force usage of our own snprintf, since we cannot test foreign snprintf
1.194 petere 1020: pgac_need_repl_snprintf=yes
1.1 petere 1021: INT64_FORMAT='"%lld"'
1022: ]) ],
1.194 petere 1023: [ AC_MSG_RESULT([cannot test (not on host machine)])
1.1 petere 1024: # Force usage of our own snprintf, since we cannot test foreign snprintf
1.194 petere 1025: pgac_need_repl_snprintf=yes
1.1 petere 1026: INT64_FORMAT='"%lld"'
1027: ])
1028: else
1029: # here if we previously decided we needed to use our own snprintf
1030: INT64_FORMAT='"%lld"'
1031: fi
1032: else
1033: # Here if we are not using 'long long int' at all
1034: INT64_FORMAT='"%ld"'
1035: fi
1036:
1.171 petere 1037: AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1038: [Define this as the appropriate snprintf format for 64-bit ints, if any])
1.1 petere 1039:
1.194 petere 1040: if test $pgac_need_repl_snprintf = yes; then
1041: AC_LIBOBJ(snprintf)
1042: fi
1.78 petere 1043:
1.84 tgl 1044: dnl Need a #define for the size of Datum (unsigned long)
1045:
1.171 petere 1046: AC_CHECK_SIZEOF([unsigned long])
1047: AC_DEFINE_UNQUOTED(SIZEOF_DATUM, $ac_cv_sizeof_unsigned_long, [sizeof(Datum) -- don't change])
1.84 tgl 1048:
1.171 petere 1049: # Determine memory alignment requirements for the basic C data types.
1.1 petere 1050:
1.6 petere 1051: PGAC_CHECK_ALIGNOF(short)
1052: PGAC_CHECK_ALIGNOF(int)
1053: PGAC_CHECK_ALIGNOF(long)
1.171 petere 1054: if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1.6 petere 1055: PGAC_CHECK_ALIGNOF(long long int)
1.1 petere 1056: fi
1.6 petere 1057: PGAC_CHECK_ALIGNOF(double)
1.1 petere 1058:
1.171 petere 1059: # Compute maximum alignment of any basic type.
1060: # We assume long's alignment is at least as strong as char, short, or int;
1061: # but we must check long long (if it exists) and double.
1062:
1063: MAX_ALIGNOF=$pgac_cv_alignof_long
1064: if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1065: MAX_ALIGNOF=$pgac_cv_alignof_double
1066: fi
1067: if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1068: MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1.1 petere 1069: fi
1.6 petere 1070: AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any type])
1.1 petere 1071:
1.155 petere 1072:
1.152 momjian 1073: # Some platforms predefine the types int8, int16, etc. Only check
1.171 petere 1074: # a (hopefully) representative subset.
1075: AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1076: [#include <stdio.h>
1.155 petere 1077: #ifdef HAVE_SUPPORTDEFS_H
1078: #include <SupportDefs.h>
1.171 petere 1079: #endif])
1.155 petere 1080:
1.171 petere 1081: # We also check for sig_atomic_t, which *should* be defined per ANSI
1082: # C, but is missing on some old platforms.
1083: AC_CHECK_TYPES([sig_atomic_t], [], [], [#include <signal.h>])
1.155 petere 1084:
1.152 momjian 1085:
1.6 petere 1086: PGAC_FUNC_POSIX_SIGNALS
1.195 petere 1087: if test $ac_cv_func_fseeko = yes; then
1088: AC_SYS_LARGEFILE
1089: fi
1.172 petere 1090:
1091:
1.184 tgl 1092: # Select semaphore implementation type.
1093: if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1094: AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores])
1095: SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1096: else
1097: if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1098: AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores])
1099: SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1100: else
1101: AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores])
1102: SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1103: fi
1104: fi
1105:
1106:
1107: # Select shared-memory implementation type.
1108: AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory])
1109: SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1110:
1111:
1.172 petere 1112: if test "$enable_nls" = yes ; then
1113: PGAC_CHECK_GETTEXT
1114: fi
1.1 petere 1115:
1.43 petere 1116: # Check for Tcl configuration script tclConfig.sh
1117: if test "$with_tcl" = yes; then
1118: PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1.185 petere 1119: PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1120: [TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1121: AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1.43 petere 1122: fi
1.1 petere 1123:
1.43 petere 1124: # Check for Tk configuration script tkConfig.sh
1125: if test "$with_tk" = yes; then
1126: PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1.185 petere 1127: PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1.1 petere 1128: fi
1129:
1130:
1.75 petere 1131: #
1132: # Check for DocBook and tools
1133: #
1134: PGAC_PROG_NSGMLS
1.178 petere 1135: PGAC_PROG_JADE
1136: PGAC_CHECK_DOCBOOK([3.1])
1137: PGAC_PATH_DOCBOOK_STYLESHEETS
1138: PGAC_PATH_COLLATEINDEX
1139: AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1.75 petere 1140:
1.61 petere 1141:
1.104 petere 1142: # prepare build tree if outside source tree
1.138 petere 1143: # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1144: # Note 2: /bin/pwd might be better than shell's built-in at getting
1145: # a symlink-free name.
1.171 petere 1146: if test "$no_create" != yes; then
1147: if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1.138 petere 1148: :
1.171 petere 1149: else
1150: AC_SUBST(vpath_build, yes)
1151: _AS_ECHO_N([preparing build tree... ])
1152: pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1153: $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1.104 petere 1154: || AC_MSG_ERROR(failed)
1155: AC_MSG_RESULT(done)
1.171 petere 1156: fi
1.61 petere 1157: fi
1.1 petere 1158:
1.171 petere 1159:
1160: AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1161:
1162: AC_CONFIG_LINKS([
1163: src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1.184 tgl 1164: src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1165: src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1.171 petere 1166: src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1167: src/include/pg_config_os.h:src/include/port/${template}.h
1168: src/Makefile.port:src/makefiles/Makefile.${template}
1169: ])
1170:
1171: AC_CONFIG_HEADERS([src/include/pg_config.h],
1.85 tgl 1172: [
1.133 petere 1173: # Update timestamp for pg_config.h (see Makefile.global)
1.171 petere 1174: echo >src/include/stamp-h
1.83 petere 1175: ])
1.171 petere 1176:
1177: AC_OUTPUT
PostgreSQL CVSweb <[email protected]>
![[BACK]](/https/anoncvs.postgresql.org/cvsweb/icons/back.gif){kind=icon}
Return to configure.in CVS log ![[TXT]](/https/anoncvs.postgresql.org/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/https/anoncvs.postgresql.org/cvsweb/icons/dir.gif){kind=icon}
Up to [PostgreSQL CVS Repository] / pgsql