EXCEL 2016

NIVEL II

Unidad Didáctica 4

“Funciones de búsqueda
Nombrar rangos”

Escuela de Informática
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

ÍNDICE DE LA UNIDAD DIDÁCTICA 4

Índice de la Unidad Didáctica 4 ................................................................................................ 2
Introducción a la Unidad Didáctica 4 ....................................................................................... 3
Objetivos .................................................................................................................................. 4
Contenidos ............................................................................................................................... 5
FUNCIONES DE BUSQUEDA ............................................................................................................... 5
BuscarV ........................................................................................................................................................ 5
BuscarH ........................................................................................................................................................ 9
Búsqueda por Aproximación ....................................................................................................................... 11
Si.Error ....................................................................................................................................................... 15
Coincidir ..................................................................................................................................................... 16
Indice ......................................................................................................................................................... 19
Asignar nombre a un rango de celdas .......................................................................................................... 22
Modificar el nombre de un rango de celdas................................................................................................. 23
Eliminar un nombre de un rango de celdas .................................................................................................. 24

Actividad de resolución .......................................................................................................... 25

Resumen................................................................................................................................. 30
Autoevaluación ...................................................................................................................... 31

Página 2 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

INTRODUCCIÓN A LA UNIDAD DIDÁCTICA 4

A esta altura del curso el alumno maneja una cierta cantidad de funciones de tipo:
matemático, de fecha y hora, estadístico y lógico.

Esta Unidad está dedicada a conocer las funciones BuscarV, BuscarH, INDICE y COINCIDIR
pertenecientes a la categoría de Búsqueda y Referencia.

Estas funciones permiten buscar un dato dentro de una tabla auxiliar o bien en otra planilla.
De manera, de obtener otro valor relacionado al dato encontrado. Se puede dar la posibilidad
que el dato buscado exista o no dentro la otra tabla auxiliar.

Estas funciones son particularmente útiles para reemplazar a la función SI, cuando las
condiciones superan los niveles de anidación que permite esta función.

También se tratará la función Si.Error es útil de conocer para reemplazar un mensaje de

error, por otro personalizado. Por ejemplo, en el caso de no encontrar un valor buscado.

Por último, el nombrar rango de celdas para aplicarla en funciones, como ser las de
búsqueda.

Página 3 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

OBJETIVOS
 Funciones de búsqueda.

 Función SI.Error

 Nombrar rango de celdas, modificarlos o eliminarlos.

Página 4 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

CONTENIDOS
FUNCIONES DE BUSQUEDA
Las funciones de búsqueda y referencia en Excel permiten encontrar valores dentro de una
Hoja de acuerdo a los criterios establecidos en la búsqueda. También ayudan a obtener
información de referencia de las celdas.

Excel provee una serie de funciones para hacer esas búsquedas en forma rápida y eficaz.
Estos resultados, una vez obtenidos, pueden simplemente mostrarse o bien utilizarse como
argumentos de otras funciones.

En esta Unidad se tratan dos funciones de búsqueda que son BuscarV, BuscarH, INDICE y
COINCIDIR que se detallan a continuación:

BUSCARV
Esta función permite buscar un dato específico dentro de otra tabla y saber si existe o no.

La búsqueda la realiza de manera vertical a lo largo de la primera columna de una tabla, a

eso se debe la letra V al final de su nombre (BuscarV). El sentido de la búsqueda es de arriba
hacia abajo.

El dato a buscar puede ser un texto, número, una referencia de celda, un resultado de una
fórmula o función.

En el caso de encontrar el dato, devuelve el contenido de otra celda que se está en la misma
fila del dato encontrado y hacia la derecha del mismo.

La tabla de búsqueda puede estar en la misma Hoja, en distinta Hoja e inclusive en diferente
Libro.

Esta función permite indicar si se desea buscar el dato exacto, o bien, una aproximación al
valor buscado.

Los ejemplos que se detallan a continuación, ayudan a comprender el manejo de esta

función. Además, se encuentran videos complementarios para una mejor comprensión.

Para que la búsqueda se realice correctamente y el valor devuelto sea el esperado, deben
cumplirse ciertas condiciones que se explican a continuación:

La sintaxis es:

=BUSCARV(valor_buscado;matriz_buscar_en;indicador_columnas;ordenado)

La función tiene 4 argumentos:

1. Valor_buscado: es el valor a buscar en la primera columna en la matriz (cuya

referencia está determinada por el segundo argumento). Este valor puede ser un
texto, número, una referencia de celda, un resultado de una fórmula o función.
2. Matriz_buscar_en: es la referencia del rango de celdas de una tabla (formada
por dos o más columnas de datos). Se debe seleccionar sin los títulos y a partir
de la columna donde se busca el valor hasta abarcar la última columna de la tabla.

Página 5 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

El rango de celdas de la matriz, debe fijarse con referencia absoluta, para que se
mantenga invariable al copiar la función.
Importante:
La primera columna de la matriz, debe ser la que contenga los valores a
buscar (indicado en el primer argumento Valor Buscado).
Esto significa que, si en la Tabla existieran otras columnas a la izquierda de los
valores buscados, éstas quedarían sin seleccionar en la matriz.

3. Indicador_columnas: es un número que indica la columna de la matriz a buscar,

desde la cual se toma el dato que devuelve la función. Este dato debe estar a la
derecha del valor buscado.
Importante:
Tener en cuenta que se comienza a contar a partir de la primera columna de la
matriz (indicada en el segundo argumento) hacia la derecha.

4. Ordenado: es un valor lógico que puede ser:

 VERDADERO (puede omitirse o escribir 1) busca por aproximación. Si no
encuentra el dato exacto, devuelve el menor valor encontrado, más próximo.
 FALSO (o escribir 0), busca solamente por coincidencia exacta. Si no lo
encuentra devuelve el mensaje de error #N/A.

Ejemplo 1: BUSQUEDA POR COINCIDENCIA EXACTA

Buscar cada Código de la planilla principal en la Tabla Auxiliar, de manera que una vez
encontrado, se obtenga la Descripción del código correspondiente. De no encontrarlo,
presenta un mensaje de error.

Este ejercicio se encuentra resuelto en este VIDEO para una mejor comprensión de la
función BUSCARV.
Hacer Ctrl-clic en este vínculo, y se ejecutará automáticamente. O bien, copiarlo en un
navegador:
https://youtu.be/LCRXCUILtjk
También se encuentran los pasos detalladas a continuación.
Página 6 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Ubicarse en la celda C3 donde se desea obtener el dato e insertar la función BUSCARV

(debido a que la búsqueda del código en la Tabla Auxiliar se realiza verticalmente a lo
largo de la columna Códigos).

1. Valor Buscado: B3
Seleccionar la celda B3 que contiene el 1er código a buscar “JK”.
2. Matriz buscar en: $B$15:$D$20
Seleccionar de la Tabla Auxiliar, el rango de celdas sin los títulos.
Como esta función se la debe copiar luego al resto de las celdas de la columna
Descripción, es importante fijar las celdas del rango de la matriz para que no
cambien al realizar la copia. Para eso, se las convierte en celdas absolutas
agregando el signo $ en las referencias (Columna y Fila) de dichas celdas.
Importante:
La primera columna de la matriz a seleccionar debe ser la que contenga los
valores a buscar (Códigos) en el primer argumento Valor Buscado.
Esto significa que, si en la Tabla Auxiliar existiera la columna A con Items que
enumeren los Códigos, esta columna quedaría sin seleccionar en la matriz.

3. Indicador de columnas: 2
Escribir un número entero que indica de cuál de las columnas de la matriz de
búsqueda, se tomará el dato que devolverá la función. En este caso, la Descripción
está en la 2da columna de la matriz.
4. Ordenado: FALSO
Al escribir este valor lógico o un 0, se pide buscar la coincidencia exacta.
En caso de no encontrar el código buscado, devuelve el mensaje de error #N/A
5. Aceptar y copiar la función al resto de la columna Descripción.
=BUSCARV(B3;$B$15:$D$20;2;FALSO)

Página 7 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Observar
En caso de modificar en la planilla principal el código JK por XXX, al no encontrarlo
en la Tabla Auxiliar, dará el mensaje de error N/A.

Ejemplo 2: BUSQUEDA POR COINCIDENCIA EXACTA

Buscar cada Código de la planilla principal en la Tabla Auxiliar, de manera que una vez
encontrado, se obtenga la Precio del código correspondiente y se lo multiplique por la
Cantidad correspondiente. De no encontrarlo, presenta un mensaje de error.

Este ejercicio se encuentra resuelto en este VIDEO para una mejor comprensión de la
función BUSCARV.
Hacer Ctrl-clic en este vínculo, y se ejecutará automáticamente. O bien, copiarlo en un
navegador:
https://youtu.be/BdhMo_EOtTg
También se encuentran los pasos detalladas a continuación.

Nro de columna de la
matriz donde se
encuentra el Precio que
se desea obtener.

Desde la barra de fórmula, a continuación de la función BuscarV (que obtiene el Precio),

multiplicarla por el Precio (D3). Al dar Enter se obtiene el Importe:
=BUSCARV(B3;$B$15:$D$20;3;FALSO)*D3

Página 8 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

BUSCARH
Esta función permite buscar un dato específico dentro de otra tabla y saber si existe o no.

La búsqueda la realiza de manera horizontal a lo largo de la primera fila de una tabla, a

eso se debe la letra H al final de su nombre (BuscarH). El sentido de la búsqueda es de
izquierda hacia la derecha.

El dato a buscar puede ser un texto o número, una referencia de celda, un resultado de una
fórmula o función.

En el caso de encontrar el dato, devuelve el contenido de otra celda que está en la misma
columna del dato encontrado.

La tabla de búsqueda puede estar en la misma Hoja, en distinta Hoja e inclusive en diferente
Libro.

Esta función permite indicar si se desea buscar el dato exacto, o bien, una aproximación al
valor buscado.

Los ejemplos que se detallan a continuación, ayudan a comprender el manejo de esta

función. Además, se encuentran videos complementarios para una mejor comprensión.

Para que la búsqueda se realice correctamente y el valor devuelto sea el esperado, deben
cumplirse ciertas condiciones que se explican a continuación:

La sintaxis es:
=BUSCARH(valor_buscado;matriz_buscar_en;indicador_filas;ordenado)
La función tiene 4 argumentos:
1. Valor_buscado: es el valor a buscar en la primera fila en la matriz (cuya
referencia está determinada por el segundo argumento). Este dato puede ser un
texto, número, una referencia de celda, un resultado de una fórmula o función.
2. Matriz_buscar_en: es la referencia del rango de celdas de una tabla (formada
por dos o más filas de datos). Se debe seleccionar sin títulos y a partir de la fila
donde se busca el valor hasta abarcar la última fila de la tabla.
El rango de celdas de la matriz, debe fijarse con referencia absoluta, para que se
mantenga invariable al copiar la Función
Importante:
La primera fila de la matriz, debe ser la que contenga los valores a buscar
(indicado en el primer argumento Valor Buscado).
Esto significa que, si en la Tabla existieran otras filas por encima de los valores
buscados, éstas quedarían sin seleccionar en la matriz.

3. Indicador_filas: es un número que indica la fila de la matriz a buscar, desde la

cual se toma el dato que devuelve la función. Este dato debe estar por debajo
del valor buscado.
Importante:
Tener en cuenta que se comienza a contar a partir de la primera fila de la matriz
(indicada en el segundo argumento) hacia la abajo.

Página 9 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

4. Ordenado: es un valor lógico (VERDADERO o FALSO).

 Si es VERDADERO (o se omite o se escribe 1), busca por aproximación. Si
no encuentra el dato exacto, devuelve el menor valor encontrado, más
próximo al inmediato superior.
 Si es FALSO (o se escribe 0), busca solamente por coincidencia exacta. Si
no lo encuentra devuelve el mensaje de error #N/A.

Ejemplo 1: BUSQUEDA POR COINCIDENCIA EXACTA

Buscar cada Código de la planilla principal en la Tabla Auxiliar, de manera que una vez
encontrado, se obtenga la Descripción del código correspondiente. De no encontrarlo,
presenta un mensaje de error.

Este ejercicio se encuentra resuelto en este VIDEO para una mejor comprensión de la
función BUSCARV.
Hacer Ctrl-clic en este vínculo, y se ejecutará automáticamente. O bien, copiarlo en un
navegador:
https://youtu.be/DJsZhk_9biY
También se encuentran los pasos detalladas a continuación.
.
Ubicarse en la celda C3 donde se desea obtener el dato e insertar la función BUSCAR H
(debido a que la búsqueda de los códigos en la Tabla Auxiliar se realiza horizontalmente a lo
largo de la fila 14).

Página 10 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

1. Valor Buscado: B3
Seleccionar la celda B3 que contiene el 1er código a buscar “JK”.
2. Matriz buscar en: $C$14:$H$16
Convertir en absolutas las celdas del rango de la matriz para que no cambien al
realizar la copia.
3. Indicador de fila: 2
Escribir un número entero que indica de cuál de las filas de la matriz a buscar,
se tomará el dato que devolverá la función. En este caso, la Descripción está en
la 2da fila de la matriz.
4. Ordenado: FALSO
Al escribir este valor lógico (o un 0), se pide buscar la coincidencia exacta.
En caso de no encontrar el código buscado, devuelve el mensaje de error #N/A.
Aceptar y copiar la función al resto de la fila Descripción.
=BUSCARV(B3;$C$14:$H$16;2;FALSO)

BÚSQUEDA POR APROXIMACIÓN

Al completar el cuarto argumento con VERDADERO o tenerlo vacío, la función BUSCARV o
BUSCARH busca por aproximación.
En caso de no encontrar el dato buscado, devuelve el valor menor que más se le aproxima
al buscado.
Importante
Es necesario que la primera columna / fila esté ordenada en forma ascendente.

Página 11 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Ejemplo 2: BUSCARH
Buscar cada Año de la planilla principal en la Tabla Auxiliar, de manera que una vez
encontrado, se obtenga la Edad Histórica del año correspondiente. De no encontrarlo, que
devuelva la Edad del valor menor más próximo al año buscado.

En este ejemplo se consideran los siguientes rangos de números correspondientes a los

diferentes períodos históricos:
 Edad Antigua  1 al 475
 Edad Media  476 al 1452
 Edad Moderna  1453 al 1789

Este ejercicio se encuentra resuelto en este VIDEO para una mejor comprensión de la
función BUSCARV.
Hacer Ctrl-clic en este vínculo, y se ejecutará automáticamente. O bien, copiarlo en un
navegador:
https://youtu.be/YarLDzxgFp4
También se encuentran los pasos detalladas a continuación.

Ubicarse en la celda C2 donde se desea obtener el dato e insertar la función BUSCARH

(debido a que la búsqueda de los Años en la Tabla Auxiliar se realiza horizontalmente a lo
largo de la fila 14).

1. Valor Buscado: B2
Seleccionar la celda B2 que contiene el 1er código a buscar “JK”.
Página 12 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

2. Matriz buscar en: $B$14:$E$15

Convertir en absolutas las celdas del rango de la matriz para que no cambien al
realizar la copia de la función.
3. Indicador de columnas: 2
Escribir un número entero que indica de cuál de las filas de la matriz a buscar,
se tomará el dato que devolverá la función. En este caso, la Edad se encuentra
en la fila 2 de la matriz.
4. Ordenado: VERDADERO
Al escribir este valor lógico, se pide buscar la coincidencia por aproximación.
En caso de no encontrar el año buscado, devuelve la Edad inferior más próxima a
la buscada en la matriz.
Aceptar y copiar la función al resto de la columna Descripción.
=BUSCARH(B2;$B$14:$E$15;2;VERDADERO)

Ejemplo 2: BUSCARV
Dada una lista con los promedios de los alumnos, en la última columna debe aparecer el
Concepto que depende del promedio obtenido que se toma de una tabla auxiliar. Esta
establece que es: “Insuficiente” para promedios menores a 4, “Regular” si está entre 4 y 7
(excluyendo el 7),” Bueno” si está entre 7 y 9 (excluyendo el 9), “Muy Bueno” si está entre
9 y 10 (excluyendo el 10) y “Excelente” si la nota es 10.

Página 13 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Ubicarse en la celda C2 donde se desea obtener el dato e insertar la función BUSCAR V

(debido a que la búsqueda de las notas en la Tabla Auxiliar se realiza verticalmente a lo largo
de la columna.

1. Valor Buscado: B2
Seleccionar la celda B2 que contiene la 1ra nota del alumno.
2. Matriz buscar en: $E$4:$F$8
Convertir en absolutas las celdas del rango de la matriz para que no cambien al
copiar luego la función.
3. Indicador de columna: 2
Escribir un número entero que indica de cuál de las columnas de la matriz a
buscar, se tomará el dato que devolverá la función. En este caso, el Concepto
está en la 2da columna de la matriz.
4. Ordenado: VERDADERO (u omitido)
Al escribir este valor lógico, se pide buscar la coincidencia por aproximación.
En caso de no encontrar la nota buscada, devuelve el concepto de la nota inferior
más próxima a la buscada.
Aceptar y copiar la función al resto de la columna Concepto.
=BUSCARV(B2;$E$4:$F$8;2;VERDADERO)

Página 14 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

SI.ERROR
Esta función permite detectar si el resultado de una fórmula o función devuelve un error.
Los tipos de error que reconoce son: #N/A, #¡VALOR!, #¡REF!, #¡DIV/0!, #¡NUM!, #¿NOMBRE?
o #¡NULO!.
La sintaxis es:
=SI.ERROR(valor;valor_si_error)
La función tiene 2 argumentos:
1. Valor: contiene la fórmula o función que se va a evaluar
2. Valor_si_error: es el dato que devuelve en el caso de que el primer argumento
devuelva un error.

Ejemplo 1: Mensaje de error al no encontrar el valor buscado en la función BUSCARV.

Como se vio anteriormente en el Ejercicio 1 de la función BuscarV, ante el ingreso de un
código inexistente en la Tabla Auxiliar, muestra el mensaje de error N/A. Esto se puede
evitar, incorporando la función SI.ERROR:

=BUSCARV(B7;$B$15:$D$20;2;FALSO) =SI.ERROR(BUSCARV(B7;$B$15:$D$20;2;
FALSO);"Código inexistente")

Nota:
Esta función presenta el mensaje en el caso de encontrar un error en la función. De lo
contrario, muestra el resultado de la función.

Página 15 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Ejemplo 2:
Mensaje de error al realizar una fórmula con una celda alfanumérica.
En ese caso, muestra el mensaje de error #VALOR. Esto se puede evitar, incorporando la
función SI.ERROR:
=B2*C2 =SI.ERROR(B2*C2;"Dato no válido")

Funciones INDICE y COINCIDIR

Existen otras funciones que ayudan a realizar búsquedas dentro de una Hoja de cálculo.
Entre ellas se encuentran la función Indice y Coincidir que se pueden complementar para
lograr obtener un dato que se encuentra en la intersección de una fila y columna de un
rango de datos.
Esta combinación de funciones es interesante para obtener cualquier tipo de dato que se
encuentre en cualquier punto de coordenada de una matriz a buscar.
Hay que recordar que la función BuscarV no permite devolver un dato que se encuentre a
la izquierda del valor buscado. Ocurre lo mismo con la función BuscarH que no permite
devolver un valor que se encuentre por encima del valor buscado. Este tipo de
inconveniente se resuelve aplicando las funciones Indice y Coincidir de manera conjunta.
A continuación, se explica cada una de las funciones:

COINCIDIR
Esta función permite localizar un dato dentro de un rango de celdas y devuelve su
posición.
La sintaxis es:
=COINCIDIR(valor buscado;matriz buscada;tipo de coincidencia)
La función tiene 3 argumentos:
1. Valor buscado: es el valor que se pretende buscar
2. Matriz buscada: se refiere al rango de celdas donde se realiza la búsqueda.
3. Tipo de búsqueda: (opcional) -es un número para indicar el tipo de búsqueda.
1  Devuelve la posición del valor inmediato inferior al valor buscado.
Es necesario que la matriz de búsqueda esté previamente ordenada de
manera ascendente.
0  Devuelve la posición del valor que es exactamente igual al valor buscado.
La matriz de búsqueda puede estar en cualquier orden.
Página 16 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

-1  Devuelve la posición del valor inmediato superior al valor buscado.

Es necesario que la matriz de búsqueda esté previamente ordenada de manera
descendente.
Cuando no se especifica el tercer argumento de la función, el valor predeterminado es 1.

Ejemplo:
Obtener el Nro de posición, dentro de la planilla, correspondiente a la “Sucursal” y “Año de
Venta” que se especifique en las celdas C16 y D16 respectivamente.

Ubicarse en la celda C17, insertar la función COINCIDIR y completar los argumentos:

Página 17 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

En este caso se busca la sucursal Núñez, dentro del rango A3:A12 con tipo de coincidencia
exacta. Al Aceptar, se obtiene la posición el dato buscado  fila 7 del rango a buscar.

Nro de fila de la
Sucursal Núñez
(dentro del rango
de sucursales)

Repetir los mismos pasos para obtener la posición del Año de Venta solicitado en D16:

Al Aceptar, se obtiene la posición el dato buscado  columna 4 del rango a buscar.

Nro de columna
del Año de
Ventas 2018
(dentro del
rango de años)

Página 18 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

INDICE
Esta función devuelve el contenido de una celda que se obtiene de la intersección de una
fila con una columna de un rango de celdas.
Tiene dos sintaxis, matricial y de referencia:

La sintaxis matricial es la que se aplica para hacer una búsqueda.

INDICE(matriz;num_fila; num_columna)
La función tiene 3 argumentos:
1. Matriz: es el rango de celdas donde se realiza la búsqueda de la intersección de la fila
y columna especificada en los siguientes parámetros.
2. Fila_num: es el número de fila de la celda cuyo contenido se necesita recuperar.
3. Num_colum: es el número de columna de la celda cuyo contenido se necesita
recuperar.

Ejemplo:
Basado en la planilla anterior, obtener el Valor de venta correspondiente a la Sucursal y Año
de Venta solicitado.

Ubicarse en la celda C21, insertar la función INDICE y completar los argumentos:

Página 19 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

En este caso se localiza en la matriz de datos B3:F12 la celda que se encuentra en la

intersección de fila y columna indicado en el nro de posición de la sucursal (C17) y año de
venta (D17) solicitado.
Al Aceptar, se obtiene el contenido de la celda buscada.

Observar:
Al modificar el valor buscado por otra Sucursal y otro Año de Venta, automáticamente
se actualiza el Nro posición de cada uno y también al Valor de la venta correspondiente,

Anidar funciones INDICE y COINCIDIR

Otra manera de resolver el ejercicio anterior es anidando las funciones:
=INDICE(B3:F12;COINCIDIR(C15;A3:A12;0);COINCIDIR(D15;B2:F2;0))

Página 20 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Otro caso para aplicar estas funciones anidadas:

Según el Código de Dpto que se ingrese en la celda amarilla (C8), se deben obtener la
Superficie (C9) y el Valor (C10) correspondiente a dicho código.

En este caso, se debe buscar el dato que se ingrese en la celda C8 dentro del rango de
celdas A3:C6. Al encontrarlo, se debe recuperar un valor que se encuentra a la izquierda
del dato buscado. Esto no es posible lograrlo con la función BuscarV. Es por esta razón
que se necesita aplicar la función INDICE junto con COINCIDIR.
Cada resultado se obtiene de la siguiente manera:

En los parámetros de la función índice se detalla:

Matriz: A3:C6 (donde se busca localizar la celda indicada en la intersección fila / columna.
Nro_fila. La función COINCIDIR busca la Código Dpto (C8), dentro del rango C3:C6, de
manera exacta, para obtener el nro de fila en donde se encuentra dicha celda.
Nro_columna: En este caso, se escribe 1 para indicar el nro de columna que se refiere a
la Superficie. Este puede ser 2 en caso de referirse al Valor.
De esta manera, se logra obtener el contenido de la celda que se encuentra en el punto de
intersección indicado por la número de la fila y columna.

Página 21 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

ASIGNAR NOMBRE A UN RANGO DE CELDAS

Se puede asignar un nombre a un rango de celdas para luego utilizarlo dentro de una función.
Esto se logra de dos maneras posibles:
Cuadro de Nombre: Etiqueta Fórmulas

-

A continuación, se detallan un ejemplo en donde se aplica un PROMEDIO haciendo referencia

a un nombre de celdas. Y otro ejemplo con la función BUSCARV en donde se aplica el Nombre
de celdas a la matriz de búsqueda.
Ejemplo1:
Obtener un PROMEDIO haciendo referencia a un nombre de celdas.
1. Dar nombre al rango: 2. Calcular
a. Seleccionar el rango B2:B8 a. Ubicarse en la celda C10
b. En el Cuadro de Nombres b. =PROMEDIO(PRECIOS)
escribir “PRECIOS” c. Enter
c. Dar Enter para confirmar

Página 22 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Ejemplo 2:
En el siguiente ejercicio, aplicar la función BuscarV sobre una matriz de búsqueda cuyo rango
tenga un nombre definido.
1. Dar nombre al rango: 2. Calcular
a. Seleccionar el rango B15:D20
3. Ubicarse en la celda C3
b. En el Cuadro de Nombres escribir
“CODIGOS” 4. =BUSCARV(B3;CODIGOS;2;FALSO)
c. Dar Enter para confirmar 5. Enter

Observar:
Al copiar la función BuscarV, no es necesario fijar el rango de celdas que conforma la matriz,
debido a que este rango se encuentra definido bajo un nombre. Esto significa que se
mantendrá fijo al copiar la función a lo largo de la columna.

MODIFICAR EL NOMBRE DE UN RANGO DE CELDAS

Página 23 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Al seleccionar el nombre del rango y hacer clic en Modificar, se abre la siguiente ventana
para modificar el rango y Aceptar.

ELIMINAR UN NOMBRE DE UN RANGO DE CELDAS

Etiqueta Fórmulas  botón Administrador de nombres  seleccionar grupo 

Página 24 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

ACTIVIDAD DE RESOLUCIÓN
Para fijar los conocimientos y a modo de práctica se le sugiere realizar la
siguiente actividad:

 Ejercicio1:
1. Armar una planilla como indica el modelo:

2. Calcular la columna de Superficie (Ancho * Largo)

3. Calcular la columna de Importe teniendo en cuenta:
 El tipo de piso.
 La superficie del local.
 El valor del metro cuadrado que deberá tomarse de la tabla
A17:B21, utilizando una función de búsqueda en tabla.
4. Calcular en E15 la suma de las superficies y en F15 la de los importes.

 Ejercicio 2:
Escribir esta tabla auxiliar a partir de la celda D17. Escribir en la celda G1 el
título “Importe 2”. En dicha columna realizar el mismo cálculo del importe
tomando el metro cuadrado de esta tabla auxiliar.

Página 25 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

 Ejercicio 3:
Escribir en la celda H1 el título “Importe 3”. En dicha columna resolver el
importe utilizando funciones SI anidadas.
 Ejercicio 4:
Hacer el listado de Sueldos del mes de Septiembre, teniendo en cuenta qué:
 El Sueldo en la columna D, depende de la categoría del empleado.
 Los Tickets son un porcentaje del sueldo.
 El Presentismo y las Retenciones se calculan sobre el Sueldo.

1. Calcular la columna de Sueldo, utilizando una función de búsqueda que

tome los valores de la tabla auxiliar.
2. Calcular el importe por Tickets, que son un porcentaje del sueldo que se
toma de la tabla auxiliar utilizando una función de búsqueda.
3. Calcular el Presentismo, que es el 20% del sueldo.
4. Calcular las Retenciones que son del 11%.
5. Calcular el Neto a cobrar.

Página 26 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Respuesta Actividad
 Ejercicio 1:
Respuesta:
1. Diseñar la planilla
2. Hallar la Superficie en E2, ingresar la fórmula: =B2*C2
Copiar la fórmula hasta E13.
3. En F2 aplicar la siguiente fórmula:
=BUSCARV(D2;$A$18:$B$21;2;FALSO)*E2
 Realizar la búsqueda exacta del tipo de piso (D2) en la tabla auxiliar
($A$18:$B$21). Al encontrarlo, obtiene el valor por m2 (de la
columna 2).
 Tener en cuenta que la matriz de búsqueda (tabla auxiliar) se fija
con dirección absoluta ($columna$fila). De manera que no se
modifique al copiarla al resto de la columna.
 Una vez que se obtiene ese valor, se lo multiplica por la superficie
E2.
 Copiar la fórmula hasta F13
4. Seleccionar E15 y hacer clic en el botón Autosuma. Luego hacer lo mismo
para la celda F15.

La figura muestra el resultado obtenido:

Página 27 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

 Ejercicio 2:
Respuesta:
1. Diseñar la tabla auxiliar de manera horizontal a partir de la celda D17.
2. Escribir el título “Importe 2” en la celda G1
3. Ubicarse en la celda G2 y aplicar la función BuscarH:
=BUSCARH(D2;$D$17:$G$18;2;FALSO)*E2
4. Copiar la función al resto de la columna.

La figura muestra el resultado obtenido:

 Ejercicio 3:
Respuesta:
1. Escribir el título “Importe 3” en la celda H1
2. Ubicarse en la celda H2 y aplicar la función SI anidada:
=SI(D2=$A$18;E2*$B$18;SI(D2=$A$19;E2*$B$19;
SI(D2=$A$20;E2*$B$20;SI(D2=$A$21;E2*$B$21;
"PISO INEXISTENTE"))))
3. Copiar la función al resto de la columna.

Página 28 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

También pudo haberse resuelto:

=SI(D2="Parquet";$B$18;SI(D2="Alfombra";$B$19;SI(D2="Baldosa";
$B$20;$B$21)))*E2
El SI de primer nivel evalúa el contenido de D2, si es Parquet toma el valor de
$B$18. Caso contrario pregunta SI es Alfombra, en ese caso, toma el valor
de $B$19. Caso contrario pregunta SI es Baldosa, en ese caso, toma el valor
de $B$20. Caso contrario, queda como última posibilidad que sea Cerámica y
en ese caso toma el valor de $C$21.

 Ejercicio 4:
Respuesta:
1. En D3 ingresar la función:
=BUSCARV(C3;$A$14:$B$16;2;FALSO)
Busca el contenido de C3 en la primera columna de la tabla $A$14:$B$16
(matriz fijada) y devuelve el contenido de B14 (columna 2). Para que
busque la coincidencia exacta, se escribe el valor lógico FALSO. Copiar
hasta D8.
2. En E3 ingresar la función:
=BUSCARV(C3;$A$14:$C$16;3;FALSO)*D3
Las mismas consideraciones que en el punto 1. Pero en este caso el
tercer argumento es 3 para que tome el porcentaje correspondiente de
C14. Luego hay que multiplicar el porcentaje obtenido por el Sueldo que
está en D3. De esta manera se obtiene el monto correspondiente a los
Tickets. Copiar hasta E8.
3. En F3 ingresar la fórmula =D3*20% y copiarla hasta F8.
4. En G3 ingresar la fórmula =D3*11% y copiarla hasta G8.
5. En H3 ingresar la fórmula =D3+E3+F3-G3 y copiarla hasta H8.

La figura muestra el ejercicio terminado:

Página 29 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

RESUMEN
Finalizada esta Unidad, el alumno deberá estar capacitado para armar correctamente
funciones de búsqueda en tabla a través de BuscarV y BuscarH.

Utilizando las mismas, podrá resolver ejercicios de cierta complejidad, donde la toma de
decisiones presenta distintas alternativas y la función SI resulta imposible de aplicar, o bien
necesita demasiados niveles de anidación.

Conocerá la función Si.Error para detectar mensajes de error y reemplazarlo por mensajes
personalizados. Muy útil en el caso de no encontrar datos que se buscan en una tabla.

También aplicará nombre a un rango de celdas, que resultará de utilidad para definir una
matriz de búsqueda y evitar tener que fijarla.

Página 30 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

AUTOEVALUACIÓN

1. ¿Qué indica el primer argumento de las funciones BUSCARV y BUSCARH?

2. ¿Qué significa que como tercer argumento aparezca el número 3?

3. ¿En qué caso debe escribirse FALSO el cuarto argumento (Ordenado), de BUSCARV y
BUSCARH?

4. ¿Qué exigencia debe cumplir la primera columna (en BUSCARV) o fila (en BUSCARH)
cuando se omite el cuarto argumento (Ordenado)?
5. ¿Con cuál valor se queda cuando no encuentra el valor exacto y el cuarto argumento
es VERDADERO o se ha omitido?

6. Explique su interpretación de la siguiente función:

=BUSCARV(D7;$F$12:$H$18;3)

7. ¿Por qué razón se colocaron los $$ en el segundo argumento de la función del ejercicio
anterior?
8. Explique su interpretación de la siguiente función:
=BUSCARH(MIN(B2:B31);F2:J3;2)

Tomar en cuenta la tabla que se muestra como modelo y considerar que en el rango
B2:B31 hay una serie de valores que representan las temperaturas mínimas de cada
día de un mes determinado.

9. En el ejemplo anterior. ¿Qué sucede si el valor de búsqueda es mayor que 25?

Página 31 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

Respuesta Autoevaluación

1. ¿Qué indica el primer argumento de las funciones BUSCARV y BUSCARH?

Respuesta:
Es el valor que deberá buscarse en la primera columna (para BUSCARV) o en la primera
fila (para BUSCARH) de la tabla auxiliar.

2. ¿Qué significa que como tercer argumento aparezca el número 3?

Respuesta:
En el caso de BuscarV, significa que la función devuelve el contenido de la tercera
columna de la tabla auxiliar (contando de izquierda a derecha) y su intersección con
la fila del dato encontrado.
En el caso de BuscarH, significa que la función devuelve el contenido de la tercera fila
de la tabla auxiliar (contando de arriba hacia abajo) y su intersección de la columna
del dato encontrado.

3. ¿En qué caso debe escribirse FALSO en el cuarto argumento (Ordenado), de BUSCARV
y BUSCARH?
Respuesta:
Cuando se pretende buscar la coincidencia exacta debe escribirse FALSO. De no
encontrar el dato, mostrará el mensaje de error N/A.

4. ¿Qué exigencia debe cumplir la primera columna (en BUSCARV) o fila (en BUSCARH)
cuando se omite el cuarto argumento (Ordenado)?
Respuesta:
Debe estar ordenada ascendentemente.

5. ¿Con cuál valor se queda cuando no encuentra el valor exacto y el cuarto argumento
es VERDADERO o se ha omitido?
Respuesta:
Con el menor más próximo.

6. Explique su interpretación de la siguiente función:

=BUSCARV(D7;$F$12:$H$18;3)
Respuesta:
 Busca el contenido de la celda D7 en la columna F a partir de la fila 12, hasta que
encuentra un valor igual o mayor.
 Si el valor encontrado es igual, devuelve el contenido de la celda de la 3er
columna (H) correspondiente a esa fila.
 Si el valor encontrado es mayor, devuelve el contenido de la celda de la columna
H de la fila anterior.

Página 32 de 33
Materia: “Excel 2016 Nivel II”
Unidad Didáctica 4
Funciones de búsqueda. Nombrar celdas.

7. ¿Por qué razón se colocaron los $$ en el segundo argumento de la función del ejercicio
anterior?
Respuesta:
El segundo argumento, la matriz de búsqueda ($F$12:$H$18) tiene aplicados $ para
fijar las celdas y de esta manera no se modifique el rango al copiar la función a lo largo
de la columna.

8. Explique su interpretación de la siguiente función, teniendo en cuenta la tabla que se

muestra como modelo y considerando que en el rango B2:B31 se encuentran una serie
de valores que representan las temperaturas mínimas de cada día de un mes
determinado.
=BUSCARH(MIN(B2:B31);F2:J3;2)

Respuesta:
Esta función busca especificar cómo fue el clima en el mes de acuerdo a la temperatura
mínima registrada en el mismo.
Para obtenerlo realiza lo siguiente:
 Busca el valor mínimo en el rango B2:B31.
 Busca por aproximación ese valor en F2:J2 (primera fila de la tabla).
 Si el valor encontrado es igual, devuelve el contenido de la celda de la fila 3
(segunda fila de la tabla indicada como segundo argumento) correspondiente
a la columna donde encontró el valor.
Si el valor encontrado es mayor, devuelve el contenido de la celda de la fila 3 de la
columna anterior.

9. En el ejemplo anterior. ¿Qué sucede si el valor de búsqueda es mayor que 25?

Respuesta:
Devuelve el dato encontrado en J3 (Cálido).

Página 33 de 33