android首次学习反编译

最新推荐文章于 2024-04-21 22:56:08 发布

原创最新推荐文章于 2024-04-21 22:56:08 发布 · 171 阅读

1 ·

CC 4.0 BY-SA版权

文章标签：

#学习

首先：

1.APKtool
你需要先去下载这个东西待会会用到

链接奉上

进去你会看到是这个样子的然后这块需要两个东西（如图）我箭头所指第一处的方向
apktool.bat这个下载链接用不了了需手动创建一个文件复制如下代码在将文件后缀改为.bat即可
代码如下：

@echo off
setlocal
set BASENAME=apktool_
chcp 65001 2>nul >nul
 
 
set java_exe=java.exe
 
 
if defined JAVA_HOME (
set java_exe="%JAVA_HOME%\bin\java.exe"
)
 
 
rem Find the highest version .jar available in the same directory as the script
setlocal EnableDelayedExpansion
pushd "%~dp0"
if exist apktool.jar (
set BASENAME=apktool
goto skipversioned
)
set max=0
for /f "tokens=1* delims=-_.0" %%A in ('dir /b /a-d %BASENAME%*.jar') do if %%~B gtr !max! set max=%%~nB
:skipversioned
popd
setlocal DisableDelayedExpansion
 
 
rem Find out if the commandline is a parameterless .jar or directory, for fast unpack/repack
if "%~1"=="" goto load
if not "%~2"=="" goto load
set ATTR=%~a1
if "%ATTR:~0,1%"=="d" (
rem Directory, rebuild
set fastCommand=b
)
if "%ATTR:~0,1%"=="-" if "%~x1"==".apk" (
rem APK file, unpack
set fastCommand=d
)
 
 
:load
%java_exe% -jar -Duser.language=en -Dfile.encoding=UTF8 "%~dp0%BASENAME%%max%.jar" %fastCommand% %*
 
 
rem Pause when ran non interactively
for /f "tokens=2" %%# in ("%cmdcmdline%") do if /i "%%#" equ "/c" pause

将.bat文件保存到你测试的文件夹下面